app-crypt/cryptor/cryptor-1.1.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit desktop meson vala xdg

DESCRIPTION="Simple GUI application for gocryptfs"
HOMEPAGE="https://github.com/moson-mo/cryptor"
SRC_URI="https://github.com/moson-mo/cryptor/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	app-crypt/gocryptfs
	dev-libs/glib:2
	dev-libs/json-glib
	dev-libs/libgee
	x11-libs/gtk+:3
"
DEPEND="
	${RDEPEND}
"
BDEPEND="
	$(vala_depend)
"

DOCS=(README.md)

src_prepare() {
	# The TrayIcon category triggers QA Notice that the "OnlyShowIn" key must be included.
	sed -e 's/TrayIcon;//' -i resources/misc/cryptor.desktop || die
	default
	vala_setup
}

src_install() {
	meson_src_install
	einstalldocs
	domenu resources/misc/cryptor.desktop
}

pkg_postinst() {
	xdg_pkg_postinst
}

pkg_postrm() {
	xdg_pkg_postrm
}