1 files changed, 47 insertions, 0 deletions
diff --git a/sys-cluster/kube-apiserver/kube-apiserver-1.16.8.ebuild b/sys-cluster/kube-apiserver/kube-apiserver-1.16.8.ebuild
new file mode 100644
index 000000000000..c3b882854d1c
--- /dev/null
+++ b/sys-cluster/kube-apiserver/kube-apiserver-1.16.8.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit golang-build golang-vcs-snapshot
+
+EGO_PN="k8s.io/kubernetes"
+ARCHIVE_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Kubernetes API server"
+HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
+SRC_URI="${ARCHIVE_URI}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+COMMON_DEPEND="acct-group/kube-apiserver
+	acct-user/kube-apiserver"
+DEPEND="${COMMON_DEPEND}
+	dev-go/go-bindata
+	>=dev-lang/go-1.13"
+RDEPEND="${COMMON_DEPEND}"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	sed -i -e "/vendor\/github.com\/jteeuwen\/go-bindata\/go-bindata/d" -e "s/-s -w/-w/" src/${EGO_PN}/hack/lib/golang.sh || die
+	sed -i -e "/export PATH/d" src/${EGO_PN}/hack/generate-bindata.sh || die
+}
+
+src_compile() {
+	LDFLAGS="" GOPATH="${WORKDIR}/${P}" emake -j1 -C src/${EGO_PN} WHAT=cmd/${PN} GOFLAGS=-v
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin _output/bin/${PN}
+	popd || die
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotated ${PN}
+}