1 files changed, 50 insertions, 0 deletions
diff --git a/sci-libs/nfft/nfft-3.3.2.ebuild b/sci-libs/nfft/nfft-3.3.2.ebuild
new file mode 100644
index 000000000000..46c22173244f
--- /dev/null
+++ b/sci-libs/nfft/nfft-3.3.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="library for nonequispaced discrete Fourier transformations"
+HOMEPAGE="http://www-user.tu-chemnitz.de/~potts/nfft"
+SRC_URI="https://github.com/NFFT/nfft/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="doc openmp static-libs"
+
+RDEPEND="sci-libs/fftw:3.0[threads,openmp?]"
+DEPEND="${RDEPEND}"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		if ! tc-has-openmp; then
+			ewarn "OpenMP is not available in your current selected compiler"
+
+			if tc-is-clang; then
+				ewarn "OpenMP support in sys-devel/clang is provided by sys-libs/libomp,"
+				ewarn "which you will need to build ${CATEGORY}/${PN} with USE=\"openmp\""
+			fi
+
+			die "need openmp capable compiler"
+		fi
+	fi
+}
+
+src_configure() {
+	econf \
+	    --enable-all \
+		--enable-shared \
+		$(use_enable openmp) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	use doc || rm -r "${ED}/usr/share/doc/${P}/html" || die
+
+	# infft uses pkg-config to record its private dependencies
+	find "${ED}" -name '*.la' -delete || die
+}