1 files changed, 45 insertions, 0 deletions
diff --git a/media-sound/gnaural/gnaural-1.0.20110606.ebuild b/media-sound/gnaural/gnaural-1.0.20110606.ebuild
new file mode 100644
index 000000000000..0c9c8c80f53c
--- /dev/null
+++ b/media-sound/gnaural/gnaural-1.0.20110606.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+GCONF_DEBUG="no"
+
+inherit autotools gnome2
+
+DESCRIPTION="An opensource binaural-beat generator"
+HOMEPAGE="http://gnaural.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/Gnaural/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="nls"
+
+RDEPEND="
+	>=x11-libs/gtk+-2:2
+	>=gnome-base/libglade-2
+	>=dev-libs/glib-2:2
+	>=media-libs/libsndfile-1.0.2
+	>=media-libs/portaudio-19_pre20071207
+"
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	mv configure.in configure.ac || die #426262
+
+	# Install desktop file into xdg compliant location
+	sed -i -e 's@/gnome/apps/Multimedia@/applications@g' \
+		Makefile.am || die "Failed to sed Makefile.am"
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable nls)
+}