1 files changed, 63 insertions, 0 deletions
diff --git a/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-19.04.0.ebuild b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-19.04.0.ebuild
new file mode 100644
index 000000000000..9e36e7d45e41
--- /dev/null
+++ b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-19.04.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kde5
+
+DESCRIPTION="KDE Telepathy account management kcm"
+HOMEPAGE="https://community.kde.org/Real-Time_Communication_and_Collaboration"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="experimental"
+
+BDEPEND="
+	dev-util/intltool
+"
+COMMON_DEPEND="
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_kdeapps_dep kaccounts-integration)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	net-libs/accounts-qt
+	net-libs/signond
+	net-libs/telepathy-qt[qt5(+)]
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kio)
+	net-libs/libaccounts-glib
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_kdeapps_dep kaccounts-providers)
+	net-im/telepathy-connection-managers
+"
+
+src_prepare() {
+	if use experimental; then
+		mv "${S}"/data/kaccounts/disabled/*.in "${S}"/data/kaccounts/ || \
+			die "couldn't enable experimental services"
+	fi
+	kde5_src_prepare
+}
+
+pkg_postinst() {
+	if use experimental; then
+		ewarn "Experimental providers are enabled."
+		ewarn "Most of them aren't integrated nicely and may require additional steps for account creation."
+		ewarn "Use at your own risk!"
+	fi
+	kde5_pkg_postinst
+}