1 files changed, 67 insertions, 0 deletions
diff --git a/games-emulation/m64py/m64py-0.2.5_p20211222.ebuild b/games-emulation/m64py/m64py-0.2.5_p20211222.ebuild
new file mode 100644
index 000000000000..e4bd1c4b099e
--- /dev/null
+++ b/games-emulation/m64py/m64py-0.2.5_p20211222.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 qmake-utils xdg-utils
+
+EGIT_COMMIT="e24679436a93e8aae0aa664dc4b2dea40d8236c1"
+MY_P=mupen64plus-ui-python-${EGIT_COMMIT}
+
+DESCRIPTION="A frontend for Mupen64Plus"
+HOMEPAGE="
+	http://m64py.sourceforge.net/
+	https://github.com/mupen64plus/mupen64plus-ui-python/
+"
+SRC_URI="
+	https://github.com/mupen64plus/mupen64plus-ui-python/archive/${EGIT_COMMIT}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3 LGPL-3 public-domain GPL-2 BSD CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="7z rar"
+
+RDEPEND="
+	dev-python/PyQt5[gui,opengl,widgets,${PYTHON_USEDEP}]
+	dev-python/PySDL2[${PYTHON_USEDEP}]
+	media-libs/libsdl2[joystick,video]
+	>=games-emulation/mupen64plus-core-2.5:0/2-sdl2
+	7z? (
+		app-arch/p7zip
+	)
+	rar? (
+		|| (
+			dev-python/rarfile[${PYTHON_USEDEP}]
+			app-arch/unrar
+			app-arch/rar
+		)
+	)
+"
+
+python_prepare_all() {
+	# set the correct search path
+	cat >> src/m64py/platform.py <<-_EOF_ || die
+		SEARCH_DIRS = ["/usr/$(get_libdir)/mupen64plus"]
+	_EOF_
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	local -x PATH=$(qt5_get_bindir):${PATH}
+	distutils-r1_python_compile
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}