1 files changed, 51 insertions, 0 deletions
diff --git a/dev-python/zipp/zipp-3.13.0.ebuild b/dev-python/zipp/zipp-3.13.0.ebuild
new file mode 100644
index 000000000000..be10426d8ea4
--- /dev/null
+++ b/dev-python/zipp/zipp-3.13.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
+HOMEPAGE="
+	https://github.com/jaraco/zipp/
+	https://pypi.org/project/zipp/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+BDEPEND="
+	test? (
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/jaraco-itertools[${PYTHON_USEDEP}]
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# speed tests are flaky by design
+	tests/test_zipp.py::TestPath::test_implied_dirs_performance
+)
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "zipp"
+		version = "${PV}"
+		description = "Backport of pathlib-compatible object wrapper for zip files"
+	EOF
+}