xfce-base/xfce4-settings: Bump to 4.18.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/xfce-base/xfce4-settings/Manifest b/xfce-base/xfce4-settings/Manifest
index c8e84fe560be..e265f35c479e 100644
--- a/xfce-base/xfce4-settings/Manifest
+++ b/xfce-base/xfce4-settings/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-settings-4.18.2.tar.bz2 1544572 BLAKE2B 8dee6855c98426aace796c7c6fe55770ca2c4c8e0c5129fd70274a0fe6589dd797eb078d79f7fd490c39cd4e1ec1dd90439c4cc030e7594aeb27c84e6e541fa2 SHA512 3371db3952f1863763b613952585873a0b8e1bd8507a64c056a918f3d16c3313e1266cb65dc341d3ce89ab281ee5a5d2cd183b6bb4078609b843524a125769b4
+DIST xfce4-settings-4.18.3.tar.bz2 1553936 BLAKE2B 6b8ab7a520044496223ae09ca0c09c7395968a79f937773ce847921869e58aa081e943feb17e72dd7565ca572c445d41baf4a7beb20067fa90400c9181e01890 SHA512 81a79a886966a5f017f066ece6ad134d132b1fa18c4f8b203212fb56b45a62fe8d9814f3039cc9bda41c52338b7e80685e9671cd80db3f2f9bcd99dd7bc47d8e
 DIST xfce4-settings-4.19.0.tar.bz2 2370986 BLAKE2B 64a25238afffb99fefe488d2218652ce714af7f783620ed5dc9d848911293bec25f95d81089cc9bb971f73e55a861c4953ebb9affd501eeb10f27a49dfc1b01b SHA512 8892d19f723bfacea1c7df8afa5abc7d45984f8b1070b24316cb8ca04ef621489632314ce1e361eda94e036df7a36b4a7988a7853469bbad1bde9e6bef9113d6
diff --git a/xfce-base/xfce4-settings/xfce4-settings-4.18.3.ebuild b/xfce-base/xfce4-settings/xfce4-settings-4.18.3.ebuild
new file mode 100644
index 000000000000..13e4a1c5b9e9
--- /dev/null
+++ b/xfce-base/xfce4-settings/xfce4-settings-4.18.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="Configuration system for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-settings/start
+	https://gitlab.xfce.org/xfce/xfce4-settings/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="colord input_devices_libinput libcanberra libnotify upower +xklavier"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.66.0
+	media-libs/fontconfig
+	>=x11-libs/gtk+-3.24.0:3
+	x11-libs/libX11
+	>=x11-libs/libXcursor-1.1
+	>=x11-libs/libXi-1.3
+	>=x11-libs/libXrandr-1.2
+	>=xfce-base/garcon-0.2:=
+	>=xfce-base/exo-4.15.1:=
+	>=xfce-base/libxfce4ui-4.17.0:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.13:=
+	colord? ( x11-misc/colord:= )
+	libcanberra? ( >=media-libs/libcanberra-0.25[sound] )
+	input_devices_libinput? ( x11-drivers/xf86-input-libinput )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	upower? ( >=sys-power/upower-0.9.23 )
+	xklavier? ( >=x11-libs/libxklavier-5 )
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable upower upower-glib)
+		$(use_enable input_devices_libinput xorg-libinput)
+		$(use_enable libnotify)
+		$(use_enable colord)
+		$(use_enable xklavier libxklavier)
+		$(use_enable libcanberra sound-settings)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}