xfce-base/xfce4-session: Bump to 4.13.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/xfce-base/xfce4-session/Manifest b/xfce-base/xfce4-session/Manifest
index 6f01c726f4e3..5e3874f99508 100644
--- a/xfce-base/xfce4-session/Manifest
+++ b/xfce-base/xfce4-session/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-session-4.12.1.tar.bz2 1289284 BLAKE2B 00af274ac1160a413c9e2c8b308dfc84248f0078e8c294528614bb642988468f9dadaae906b4a8e2179d2beef0a48ebf5e2eedcb2ed3ad7ea73a8f7a9b90e224 SHA512 d7f37dbff59acb316965ab2224674ac3b5b7cfd7262acd4426b582001cee313945acb8883be21553dd6d7a046934bbbe116f451e6d5fd35b6fa5444da94605df
 DIST xfce4-session-4.13.1.tar.bz2 1322823 BLAKE2B e50cc2628a068bed39d2aa6344eab7676e6464c84e3cf11d79518f78db54ea01316bd098a541b6f0897f3decbed2eb37e55009d4bf89d460e136d7a44d31c26a SHA512 5845e3591919e23ca176199e81075a097ef9d65cbcf23b34d84afc649a307bfa8c6492e3a01855cacff9328da809725213ec1fa9d76024c0a0c25cce3c51da1b
+DIST xfce4-session-4.13.2.tar.bz2 829041 BLAKE2B 3b5c8a5722b7a38a95e12ec2145e2c155928e0ee5d7d8e9f47c86ec4e03f34b983bcd3dcbc1a3d6c2d84f991ed8e9f59b7db76716862c91290280db507a8b84e SHA512 cb1e63a3df9c4ac3efcb0cce20cb5528f9d1a46731ad4b32634ad5f4a53711f05b40d98464bfd562b4e3d42b2555827ece03e63c6a433e879fa0f0a4ccda6a57
diff --git a/xfce-base/xfce4-session/xfce4-session-4.13.2.ebuild b/xfce-base/xfce4-session/xfce4-session-4.13.2.ebuild
new file mode 100644
index 000000000000..c9dc5edb2d0b
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.13.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="https://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="elogind nls policykit systemd +xscreensaver"
+
+COMMON_DEPEND="x11-apps/iceauth
+	>=dev-libs/glib-2.42
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libSM:=
+	x11-libs/libwnck:3=
+	x11-libs/libX11:=
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/libxfce4ui-4.12.1:=[gtk3(+)]
+	>=xfce-base/xfconf-4.12:=
+	policykit? ( >=sys-auth/polkit-0.102:= )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	nls? ( x11-misc/xdg-user-dirs )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.26
+		>=x11-misc/xlockmore-5.43
+		x11-misc/slock
+		x11-misc/alock[pam]
+	) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+REQUIRED_USE="elogind? ( policykit )
+	systemd? ( policykit )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.10.1-alock_support_to_xflock4.patch
+# TODO: this patch needs updating for the new version, and finding
+# upstream bug.
+#	"${FILESDIR}"/${PN}-4.12.1-light-locker_support_to_xflock4.patch
+)
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		--with-xsession-prefix="${EPREFIX}"/usr
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4 || die
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}