x11-wm/enlightenment: bump to 0.24

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/x11-wm/enlightenment/Manifest b/x11-wm/enlightenment/Manifest
index 1b3e26fd213f..65eb55da2e8d 100644
--- a/x11-wm/enlightenment/Manifest
+++ b/x11-wm/enlightenment/Manifest
@@ -1 +1,2 @@
 DIST enlightenment-0.23.1.tar.xz 26426096 BLAKE2B d781dc951ad8eddd90f633b29a6b1180be63e6052a56e60644b4f738f4c0d42617aeb4f7326cf3284d0b331dd87d605fa0625ea6435f4e36b8f5b3ccce82ca53 SHA512 b5b8a34f6abe47d9b23dbcaf09d2f61f74b3f8d5a97b30a9666916b4bd307a45cb2ad874288419ab40ef06fa57c3b7dc15377dd9acaeb6eb71cd8c0c24fc42cb
+DIST enlightenment-0.24.0.tar.xz 28712348 BLAKE2B 97294beaf6456ca5512796fbfbff72207e2c57aad130f802b6a63c7a9a30e8bc6cd98ad6947a1f4edb8508a96ef135b66297827edfb63c4ea4330588677a9abc SHA512 7255ec5c2e85143df8d92e37456f5392feb3a264daa81ec6b10ae57886d714c524869392ddc753914f3a9c5fd71e1b2c5dd1d1e1f7a5a649fb6aaaed81214b95
diff --git a/x11-wm/enlightenment/enlightenment-0.24.0.ebuild b/x11-wm/enlightenment/enlightenment-0.24.0.ebuild
new file mode 100644
index 000000000000..bf3eeb20a1d2
--- /dev/null
+++ b/x11-wm/enlightenment/enlightenment-0.24.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils meson xdg-utils
+
+DESCRIPTION="Enlightenment window manager"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0.17/${PV%%_*}"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="acpi bluetooth connman doc geolocation nls pam policykit systemd udisks wayland wifi xwayland"
+
+REQUIRED_USE="xwayland? ( wayland )"
+
+RDEPEND=">=dev-libs/efl-1.24.1[eet,fontconfig,X]
+	virtual/udev
+	x11-libs/libXext
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	x11-misc/xkeyboard-config
+	acpi? ( sys-power/acpid )
+	bluetooth? ( net-wireless/bluez )
+	connman? ( dev-libs/efl[connman] )
+	geolocation? ( app-misc/geoclue:2.0 )
+	pam? ( sys-libs/pam )
+	policykit? ( sys-auth/polkit )
+	systemd? ( sys-apps/systemd )
+	udisks? ( sys-fs/udisks:2 )
+	wayland? (
+		>=dev-libs/efl-1.22.0[drm,wayland]
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+		x11-libs/pixman
+	)
+	xwayland? (
+		dev-libs/efl[X,wayland]
+		x11-base/xorg-server[wayland]
+	)"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local emesonargs=(
+		-D device-udev=true
+		-D install-enlightenment-menu=true
+
+		-D install-sysactions=true
+		-D install-system=true
+		-D mount-eeze=false
+
+		-D packagekit=false
+
+		$(meson_use udisks mount-udisks)
+		$(meson_use bluetooth bluez5)
+		$(meson_use connman)
+		$(meson_use geolocation)
+		$(meson_use nls)
+		$(meson_use pam)
+		$(meson_use policykit polkit)
+		$(meson_use systemd)
+		$(meson_use wayland wl)
+		$(meson_use wifi wireless)
+		$(meson_use xwayland)
+	)
+
+	if ! use wayland; then
+		emesonargs+=(
+			-D wl-buffer=false
+			-D wl-desktop-shell=false
+			-D wl-drm=false
+			-D wl-text-input=false
+			-D wl-weekeyboard=false
+			-D wl-wl=false
+			-D wl-x11=false
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/. )
+	meson_src_install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+
+	einfo "Additional programs to complete full EFL suite: "
+	optfeature "office file thumbnails" app-office/libreoffice app-office/libreoffice-bin
+	optfeature "an EFL-based IDE" dev-util/edi
+	optfeature "image viewer" media-gfx/ephoto
+	optfeature "ConnMan user interface for Enlightenment" net-misc/econnman
+	optfeature "system and process monitor" sys-process/evisum
+	optfeature "feature rich terminal emulator" x11-terms/terminology
+	optfeature "a modern flat enlightenment WM theme" x11-themes/e-flat-theme
+	optfeature "a matching GTK theme" x11-themes/e-gtk-theme
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}