www-client/opera: remove old

Signed-off-by: Matt Jolly <Matt.Jolly@footclan.ninja>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 0 insertions, 171 deletions

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 54e1d3753fce..42151936a290 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,3 +1,2 @@
 DIST opera-ffmpeg-codecs-114.0.5735.9.tar.xz 1315192 BLAKE2B ef9a0cfc8c30ac0a837863644f3c2d5e78059575e2b8f6fda9253304f4815a39d021602e802dac7e1d5a1685aa5015a02019c4a0399f0bdc81136f956cc1d55f SHA512 bdad66bd5d238bdeb81a4e2a956f0a814633360f05c7bed2161df9506d2ccc444445ba452cc8974c755fe0d3f46adceb90324a472a5dac72e9c65391ae7a841c
-DIST opera-stable_104.0.4944.54_amd64.deb 110407764 BLAKE2B 8dd34c2b65fc1bbe6ad2401a8b8fc80e2b2022823ad4df5288ee2a4a961c8bda0462d51f570725671b950f103cf61cf16c95d2b52ff8c667804fcf8eb0b33fda SHA512 c0b8ce8c7f99042d981e03d212e49173e8df6ba9b951958ea4442eb645190dab4330c851de0d66e1d3ac5bd6fe3cadc4250c6ee6ee104b4e350d0392792fa993
 DIST opera-stable_105.0.4970.13_amd64.deb 111996508 BLAKE2B 2179bc54d0d153ff9632fa86186f85af62639a2c5e4787d3ad2845076490b074d05236f007bb2a563780503b8b77e5e95d30cbfd6135617ff14bda76192f7719 SHA512 e2ef835e7f8a5ebd30e3a01f3cee724381ab2aea86234d90a32b3ca1f1f5a765fb5006d318ac459dc50e27b3c453cb1d2b1f7282f737ad27f9a241fb3dcf245f
diff --git a/www-client/opera/opera-104.0.4944.54.ebuild b/www-client/opera/opera-104.0.4944.54.ebuild
deleted file mode 100644
index 1b66d70aadeb..000000000000
--- a/www-client/opera/opera-104.0.4944.54.ebuild
+++ /dev/null
@@ -1,170 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CHROMIUM_LANGS="
-	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-
-# These are intended for ebuild maintainer use to force RPM if DEB is not available.
-: ${OPERA_FORCE_RPM=no}
-
-inherit chromium-2 pax-utils xdg
-
-if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-	inherit rpm
-	OPERA_ARCHIVE_EXT="rpm"
-else
-	inherit unpacker
-	OPERA_ARCHIVE_EXT="deb"
-fi
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* amd64"
-
-FFMPEG_VERSION="114.0.5735.9"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
-	proprietary-codecs? (
-		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs +suid qt5 qt6"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0:2
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5[X]
-		dev-qt/qtwidgets:5
-	)
-	qt6? ( dev-qt/qtbase:6[gui,widgets] )
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rpm_src_unpack "${A[0]}"
-	else
-		unpacker
-	fi
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
-	else
-		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	fi
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rm "${OPERA_HOME}/setup_repo.sh" || die
-	else
-		rm -r "usr/share/lintian" || die
-
-		# fix docs
-		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-		gzip -d usr/share/doc/${PF}/changelog.gz || die
-	fi
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	if ! use qt5; then
-		rm "${OPERA_HOME}/libqt5_shim.so" || die
-	fi
-	if ! use qt6; then
-		rm "${OPERA_HOME}/libqt6_shim.so" || die
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
-}