www-apps/nikola: add 8.2.4

Signed-off-by: Ulrich Müller <ulm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/www-apps/nikola/Manifest b/www-apps/nikola/Manifest
index 3438a0e6cd11..5fd523602985 100644
--- a/www-apps/nikola/Manifest
+++ b/www-apps/nikola/Manifest
@@ -1 +1,2 @@
 DIST Nikola-8.2.3.tar.gz 5486641 BLAKE2B 690ea8584b9b11b1f26b768dc6daaded2f976b54a7be3b75f83d50cda3721f3f0051fd7ff7be3c38ed871ac905f604f891936e4ea72381b8f88a461f4d227587 SHA512 fbb107f975a4eeb369469eaa7a83e6fd342202530f91a0428c854f2eca28315268d6623983a078496943878a9f0548a5939184a2349d468cc0ac7152116b48b4
+DIST Nikola-8.2.4.tar.gz 5635965 BLAKE2B 94421a278718fd9ae9f8978854954f2120bab005d10a52294b120d619a67455417eed94bb9e99cc9d01eca4e1d3da210980caef1ad7ff4ca5d25299a39d8eb19 SHA512 2bcea53181a5371fc1ce7d6d96e5db1ae0ab7c4bc8fe8947ed0d5427e71a469b0f522f1e6f20a47e51a3325730a9646156a8a57bab127785f220c65eb9f891ea
diff --git a/www-apps/nikola/nikola-8.2.4.ebuild b/www-apps/nikola/nikola-8.2.4.ebuild
new file mode 100644
index 000000000000..93ffb6d32eea
--- /dev/null
+++ b/www-apps/nikola/nikola-8.2.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit bash-completion-r1 distutils-r1 optfeature pypi
+
+DESCRIPTION="A static website and blog generator"
+HOMEPAGE="https://getnikola.com/"
+SRC_URI="$(pypi_sdist_url --no-normalize ${PN^} ${PV})"
+S="${WORKDIR}/${P^}"
+
+LICENSE="MIT Apache-2.0 CC0-1.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+RESTRICT="test" # needs coveralls
+
+BDEPEND=">=dev-python/docutils-0.13[${PYTHON_USEDEP}]" # needs rst2man to build manpage
+RDEPEND="${BDEPEND}
+	>=dev-python/Babel-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/doit-0.32[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.5[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/natsort-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/piexif-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/PyRSS2Gen-1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-67.2.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-0.04.16[${PYTHON_USEDEP}]
+	>=dev-python/yapsy-1.11.223[${PYTHON_USEDEP}]
+	dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+	dev-python/cloudpickle[${PYTHON_USEDEP}]"
+
+python_compile_all() {
+	nikola tabcompletion --shell=bash > ${PN}.bashcomp || die
+	nikola tabcompletion --shell=zsh > ${PN}.zshcomp || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# hackish way to remove docs that ended up in the wrong place
+	rm -r "${ED}/usr/share/doc/${PN}" || die
+
+	dodoc AUTHORS.txt CHANGES.txt README.rst docs/*.rst
+	gunzip "${ED}/usr/share/man/man1/${PN}.1.gz" || die
+
+	newbashcomp ${PN}.bashcomp ${PN}
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zshcomp _${PN}
+}
+
+pkg_postinst() {
+	optfeature "chart generation" dev-python/pygal
+	optfeature "hyphenation support" dev-python/pyphen
+	optfeature "notebook compilation and LESS support" dev-python/ipython
+	optfeature "alternative templating engine to Mako" dev-python/jinja
+	optfeature "built-in web server support" dev-python/aiohttp
+	optfeature "monitoring file system events" dev-python/watchdog
+	optfeature "extracting metadata from web media links" dev-python/micawber
+}