sys-apps/accountsservice: Version bump to 22.07.4

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/sys-apps/accountsservice/Manifest b/sys-apps/accountsservice/Manifest
index f27b260d69e7..31cf5f420819 100644
--- a/sys-apps/accountsservice/Manifest
+++ b/sys-apps/accountsservice/Manifest
@@ -1,2 +1,3 @@
 DIST accountsservice-0.6.55.tar.xz 97972 BLAKE2B aba3adfeb53e64455ce8e672b9db754bae4af6b4de0823cc021d0311a381ec40af04371e78f7c84eab7fb72356b26e22db78aad0343d57f65ea71a7742b51fc7 SHA512 c12e6a8e80f9b087f97238da4734d2d3a14a7c5cbd870a32a04b00116f176c818c39fb886f6dc72c3e93c136b0c2074ddf8f77e20431fa3bd54f138bea9d262d
 DIST accountsservice-22.04.62.tar.xz 101740 BLAKE2B b0514e2160560816fa64688072c0534ad6375ef699459e24a083f738fe8388c2f13b2ea37acbb50c64b9823fc5391356deddfd964e22d9db722bfe6816009cb8 SHA512 4d37b09c1cb1b55dc474cb76c53cbf0a3172bb0e6a0782405c0c09b9680ee3ac02103dfd57777bf131649de2ad0ebc8063362fa7ca18edfd2cb6d2a38a886900
+DIST accountsservice-22.07.4.tar.xz 101980 BLAKE2B 68cba1c1493ee53286a72d1cf68535f112c5ff244bb0af27b6461add92f33f8dbb34d63fe0d3a3b49e33d1ed966d3ae3b3f4a4e4ac36bf04956082b46368c0bb SHA512 3dd6d71c958653109feea0e3c83f3fb5c9294be02bc025bf4ad20b4c785823d34fd703efcb1d81ecb26a4b680e218ec250307a4c1fd57dc8a15f00310d2ae408
diff --git a/sys-apps/accountsservice/accountsservice-22.07.4.ebuild b/sys-apps/accountsservice/accountsservice-22.07.4.ebuild
new file mode 100644
index 000000000000..cc2ca7bb4783
--- /dev/null
+++ b/sys-apps/accountsservice/accountsservice-22.07.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2011-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+inherit meson python-any-r1 systemd
+
+DESCRIPTION="D-Bus interfaces for querying and manipulating user account information"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/AccountsService/"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="doc elogind gtk-doc +introspection selinux systemd test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="^^ ( elogind systemd )"
+
+CDEPEND="
+	>=dev-libs/glib-2.63.5:2
+	sys-auth/polkit
+	virtual/libcrypt:=
+	elogind? ( >=sys-auth/elogind-229.4 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+	systemd? ( >=sys-apps/systemd-186:0= )
+"
+DEPEND="${CDEPEND}"
+BDEPEND="
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	)
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/python-dbusmock[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-accountsd )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-22.04.62-gentoo-system-users.patch
+)
+
+python_check_deps() {
+	if use test; then
+		has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir="${EPREFIX}/var"
+		-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
+		-Dadmin_group="wheel"
+		$(meson_use elogind)
+		$(meson_use introspection)
+		$(meson_use doc docbook)
+		$(meson_use gtk-doc gtk_doc)
+		-Dvapi=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# https://gitlab.freedesktop.org/accountsservice/accountsservice/-/issues/90
+	if use doc; then
+		mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	# This directories are created at runtime when needed
+	rm -r "${ED}"/var/lib || die
+}