net-wireless/gr-rds: update

support new python
support new gnuradio

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Rick Farina <zerochaos@gentoo.org>

3 files changed, 73 insertions, 6 deletions

diff --git a/net-wireless/gr-rds/Manifest b/net-wireless/gr-rds/Manifest
new file mode 100644
index 000000000000..737150379392
--- /dev/null
+++ b/net-wireless/gr-rds/Manifest
@@ -0,0 +1 @@
+DIST gr-rds-0.0_p20200807.tar.gz 210730 BLAKE2B be2ded79a744d97572f754458fbab6c4091eb9096fa01238e09cfb1703d50fc1f228000b973826456fe4fae7577ef4dcc871edb4f72bd4e2daacdf3d01330d03 SHA512 d04944db7c02d3a004beae5be96a42274dcc4503d94bd22b726c664fb49103c41479ce49f7b4f2e6fb86d7b6bdd01873375fd6a7a7cc4b04ec9bf033235743a2
diff --git a/net-wireless/gr-rds/gr-rds-0.0_p20200807.ebuild b/net-wireless/gr-rds/gr-rds-0.0_p20200807.ebuild
new file mode 100644
index 000000000000..e4b42b14c552
--- /dev/null
+++ b/net-wireless/gr-rds/gr-rds-0.0_p20200807.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/bastibl/${PN}"
+	EGIT_BRANCH="maint-3.8"
+else
+	KEYWORDS="~amd64 ~x86"
+	COMMIT="ffbe3ea302c32a621f14329b7fcc09e868305e78"
+	SRC_URI="https://github.com/bastibl/gr-rds/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
+fi
+inherit cmake python-single-r1
+
+DESCRIPTION="GNU Radio FM RDS Receiver"
+HOMEPAGE="https://github.com/bastibl/gr-rds"
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-libs/boost:=[${PYTHON_MULTI_USEDEP}]
+	')
+	=net-wireless/gnuradio-3.8*:0=[${PYTHON_SINGLE_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/swig:0
+"
+#cppunit is listed in cmake, but only needed for tests and there are no tests
+#	dev-util/cppunit"
+
+src_prepare() {
+	cmake_src_prepare
+	#although cppunit is not used, it fails if it isn't there, fix it
+	sed -i 's#FATAL_ERROR "CppUnit#MESSAGE "CppUnit#' CMakeLists.txt || die
+	sed -i '/${CPPUNIT_INCLUDE_DIRS}/d' CMakeLists.txt || die
+	sed -i '/${CPPUNIT_LIBRARY_DIRS}/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=( -DPYTHON_EXECUTABLE="${PYTHON}" )
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_optimize
+}
diff --git a/net-wireless/gr-rds/gr-rds-9999.ebuild b/net-wireless/gr-rds/gr-rds-9999.ebuild
index 10e9f43865de..e4b42b14c552 100644
--- a/net-wireless/gr-rds/gr-rds-9999.ebuild
+++ b/net-wireless/gr-rds/gr-rds-9999.ebuild
@@ -3,15 +3,19 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python2_7 )
+PYTHON_COMPAT=( python3_{7,8} )
 
 if [[ ${PV} == 9999* ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/bastibl/${PN}"
+	EGIT_BRANCH="maint-3.8"
 else
-	KEYWORDS=""
+	KEYWORDS="~amd64 ~x86"
+	COMMIT="ffbe3ea302c32a621f14329b7fcc09e868305e78"
+	SRC_URI="https://github.com/bastibl/gr-rds/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
 fi
-inherit cmake-utils python-single-r1
+inherit cmake python-single-r1
 
 DESCRIPTION="GNU Radio FM RDS Receiver"
 HOMEPAGE="https://github.com/bastibl/gr-rds"
@@ -25,7 +29,7 @@ RDEPEND="${PYTHON_DEPS}
 	$(python_gen_cond_dep '
 		dev-libs/boost:=[${PYTHON_MULTI_USEDEP}]
 	')
-	>=net-wireless/gnuradio-3.7_rc:0=[${PYTHON_SINGLE_USEDEP}]
+	=net-wireless/gnuradio-3.8*:0=[${PYTHON_SINGLE_USEDEP}]
 "
 DEPEND="${RDEPEND}"
 BDEPEND="
@@ -35,7 +39,7 @@ BDEPEND="
 #	dev-util/cppunit"
 
 src_prepare() {
-	cmake-utils_src_prepare
+	cmake_src_prepare
 	#although cppunit is not used, it fails if it isn't there, fix it
 	sed -i 's#FATAL_ERROR "CppUnit#MESSAGE "CppUnit#' CMakeLists.txt || die
 	sed -i '/${CPPUNIT_INCLUDE_DIRS}/d' CMakeLists.txt || die
@@ -44,5 +48,10 @@ src_prepare() {
 
 src_configure() {
 	local mycmakeargs=( -DPYTHON_EXECUTABLE="${PYTHON}" )
-	cmake-utils_src_configure
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_optimize
 }