proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 90 insertions, 0 deletions

diff --git a/net-voip/yate/yate-9999.ebuild b/net-voip/yate/yate-9999.ebuild
new file mode 100644
index 000000000000..a09f6b3ed8e9
--- /dev/null
+++ b/net-voip/yate/yate-9999.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="The Yate AV Suite"
+HOMEPAGE="http://yate.null.ro/"
+
+if [[ ${PV} == 9999 ]] ; then
+	ESVN_REPO_URI="http://voip.null.ro/svn/yate/trunk"
+	inherit subversion
+	KEYWORDS=""
+else
+	SRC_URI="http://voip.null.ro/tarballs/${PN}5/${P}-1.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="doc cpu_flags_x86_sse2 sctp dahdi zaptel wpcard tdmcard wanpipe +ilbc +ilbc-webrtc +isac-float isac-fixed postgres mysql +gsm +speex h323 spandsp +ssl qt4 +zlib amrnb"
+
+RDEPEND="
+	postgres? ( dev-db/postgresql )
+	mysql? ( virtual/mysql )
+	gsm? ( media-sound/gsm )
+	speex? ( media-libs/speex )
+	ssl? ( dev-libs/openssl )
+	h323? ( net-libs/h323plus )
+	zlib? ( sys-libs/zlib )
+	qt4? ( dev-qt/qtgui:4 dev-qt/designer:4 )
+	ilbc? ( dev-libs/ilbc-rfc3951 )
+	spandsp? ( >=media-libs/spandsp-0.0.3 )
+	dahdi? ( net-misc/dahdi )
+"
+DEPEND="doc? ( || ( app-doc/doxygen dev-util/kdoc ) )
+	virtual/pkgconfig
+	${RDEPEND}"
+
+src_prepare() {
+	eautoreconf
+	./yate-config.sh || die
+}
+
+#fdsize, inline, rtti: keep default values
+#internalregex: use system
+#coredumper: not in the tree, bug 118716
+#wanpipe, wphwec: not in the tree, bug 188939
+#amrnb: not in tree!
+#zaptel: ??
+src_configure() {
+	econf \
+		--with-archlib=$(get_libdir) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable sctp) \
+		$(use_enable dahdi) \
+		$(use_enable zaptel) \
+		$(use_enable wpcard) \
+		$(use_enable tdmcard) \
+		$(use_enable wanpipe) \
+		$(use_enable ilbc) \
+		$(use_enable ilbc-webrtc) \
+		$(use_enable isac-float) \
+		$(use_enable isac-fixed) \
+		$(use_with postgres libpq) \
+		$(use_with mysql) \
+		$(use_with gsm libgsm) \
+		$(use_with speex libspeex) \
+		$(use_with amrnb) \
+		$(use_with spandsp) \
+		$(use_with h323 openh323 /usr) \
+		$(use_with h323 pwlib /usr) \
+		$(use_with ssl openssl) \
+		$(use_with qt4 libqt4)
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	if use doc; then
+		emake DESTDIR="${ED}" install
+	else
+		emake DESTDIR="${ED}" install-noapi
+	fi
+}