net-p2p/qbittorrent: drop 4.6.6

4.6.7 is stable

Signed-off-by: Filip Kobierski <fkobi@pm.me>
Signed-off-by: Eli Schwartz <eschwartz@gentoo.org>

2 files changed, 0 insertions, 147 deletions

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index 5e4c80e97bbd..02bde8735e82 100644
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1,5 +1,3 @@
-DIST qbittorrent-4.6.6.tar.xz 4524468 BLAKE2B 20141bf0bca5dd851950e070172d509b8f7d9d59125808b304ca321f31e4ed2f6fc8e012c05c37485a900db65c5e64b88b807196270a7328e2258ec550de8a7a SHA512 5062a2fe4fa821e76b6f058c1ca761572623bb2c5bf0df288119cd67563a5e2f1811b8c24bac9a9696b4620c3a1068136523add146691b483ed19e00d1000610
-DIST qbittorrent-4.6.6.tar.xz.asc 849 BLAKE2B 56ec7c17d3c49661bc156400d6a721767fa2b90e9946b4a6e737fa712bc60dc61ec08a4db638dcc440875a217ae36823d645bbd2a913e14b35747a3128ad9d21 SHA512 09975d8200f9c6c46ace2de95f43f42924ddfebb3140a20f10db2389fc63f1f2117e28bc3084da5605b01a0c040f272bd1e638feea51ebcc4cd56df1e9cb2af4
 DIST qbittorrent-4.6.7.tar.xz 4539016 BLAKE2B 8565fdc298e5085b10b52442874ce2d9b9f253ba57bb2d1bef065d603847e5d3d838197ea2077aa80cc3db56aea4b1100fad2d7a0398fa13128d4a064286afc6 SHA512 3664c89f91a3443c74a5c76da8f66ab595bf4f48cbba2421a287d4f8bf780e06605cd0a6fa9598a5ab09e876a46d31b2f85461ef65f17410df1914acd9d37262
 DIST qbittorrent-4.6.7.tar.xz.asc 849 BLAKE2B e63d1fc1c8c6b9a70551bd717a2614b8548bd93656b578f4289d720c2784508ca90971f995fa6c8b6dc26ed6a7f976d294e44d4e384bb3de30791f26ff930017 SHA512 820e329921d23409560fa2a2f3e714b233154783da5bb8fdcf7ed70c90df69d5140d8159f8d52dc1a9b5cc32306580a08e56c02b55f0e2b00c16cbf9f6982baa
 DIST qbittorrent-5.0.0.tar.xz 4512592 BLAKE2B 156a2aae2c45d877197d50ec0c42b003dcb290d2e612b93d94f10c1c1b55fb24d6bc37cfd489b70f545bb4f390ee35634a808992441ce49e7e27de5ecb508943 SHA512 ab480c181f3a43a3e248daa35d3d3e0b121eb80bfd8a4a4d63fd504ba26441a31e7ca563fe80bc520ad1219104cf929460cfc0a5cfdad13ad61a5a316deeb695
diff --git a/net-p2p/qbittorrent/qbittorrent-4.6.6.ebuild b/net-p2p/qbittorrent/qbittorrent-4.6.6.ebuild
deleted file mode 100644
index d003502d13d5..000000000000
--- a/net-p2p/qbittorrent/qbittorrent-4.6.6.ebuild
+++ /dev/null
@@ -1,145 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake edo multibuild systemd verify-sig xdg
-
-DESCRIPTION="BitTorrent client in C++ and Qt"
-HOMEPAGE="https://www.qbittorrent.org"
-
-if [[ ${PV} == *9999 ]]; then
-	EGIT_REPO_URI="https://github.com/qbittorrent/qBittorrent.git"
-	inherit git-r3
-else
-	SRC_URI="
-		https://downloads.sourceforge.net/qbittorrent/${P}.tar.xz
-		verify-sig? ( https://downloads.sourceforge.net/qbittorrent/${P}.tar.xz.asc )
-	"
-	KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~riscv x86"
-
-	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-qbittorrent )"
-	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/qBittorrent.asc
-fi
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="+dbus +gui qt6 systemd test webui"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="|| ( gui webui )
-	dbus? ( gui )
-"
-
-RDEPEND="
-	>=dev-libs/openssl-1.1.1:=
-	>=net-libs/libtorrent-rasterbar-1.2.19:=
-	>=sys-libs/zlib-1.2.11
-	qt6? ( >=dev-qt/qtbase-6.2:6[network,ssl,sql,sqlite,xml] )
-	!qt6? (
-		dev-qt/qtcore:5
-		dev-qt/qtnetwork:5[ssl]
-		dev-qt/qtsql:5[sqlite]
-		dev-qt/qtxml:5
-	)
-	gui? (
-		!qt6? (
-			dev-qt/qtgui:5
-			dev-qt/qtsvg:5
-			dev-qt/qtwidgets:5
-			dbus? ( dev-qt/qtdbus:5 )
-		)
-		qt6? (
-			>=dev-qt/qtbase-6.2:6[dbus?,gui,widgets]
-			>=dev-qt/qtsvg-6.2:6
-		)
-	)
-	webui? (
-		acct-group/qbittorrent
-		acct-user/qbittorrent
-	)
-"
-DEPEND="
-	${RDEPEND}
-	>=dev-libs/boost-1.71
-	test? (
-		!qt6? ( dev-qt/qttest:5 )
-	)"
-BDEPEND+="
-	!qt6? ( dev-qt/linguist-tools:5 )
-	qt6? ( >=dev-qt/qttools-6.2:6[linguist] )
-	virtual/pkgconfig"
-
-DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md )
-
-src_prepare() {
-	MULTIBUILD_VARIANTS=()
-	use gui && MULTIBUILD_VARIANTS+=( gui )
-	use webui && MULTIBUILD_VARIANTS+=( nogui )
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	my_src_configure() {
-		local mycmakeargs=(
-			# musl lacks execinfo.h
-			-DSTACKTRACE=$(usex !elibc_musl)
-			# More verbose build logs are preferable for bug reports
-			-DVERBOSE_CONFIGURE=ON
-			-DQT6=$(usex qt6)
-			-DWEBUI=$(usex webui)
-			-DTESTING=$(usex test)
-		)
-
-		if [[ ${MULTIBUILD_VARIANT} == "gui" ]]; then
-			# We do this in multibuild, see bug #839531 for why.
-			# Fedora has to do the same thing.
-			mycmakeargs+=(
-				-DGUI=ON
-				-DDBUS=$(usex dbus)
-				-DSYSTEMD=OFF
-			)
-		else
-			mycmakeargs+=(
-				-DGUI=OFF
-				-DDBUS=OFF
-			)
-
-			use systemd && mycmakeargs+=(
-				# The systemd service calls qbittorrent-nox, which is only
-				# installed when GUI=OFF.
-				-DSYSTEMD=ON
-				-DSYSTEMD_SERVICES_INSTALL_DIR="$(systemd_get_systemunitdir)"
-			)
-		fi
-
-		cmake_src_configure
-	}
-
-	multibuild_foreach_variant my_src_configure
-}
-
-src_compile() {
-	multibuild_foreach_variant cmake_src_compile
-}
-
-src_test() {
-	my_src_test() {
-		# cmake does not detect tests by default, if you use enable_testing
-		# in a subdirectory instead of the root CMakeLists.txt
-		cd "${BUILD_DIR}"/test || die
-		edo ctest .
-	}
-
-	multibuild_foreach_variant my_src_test
-}
-
-src_install() {
-	multibuild_foreach_variant cmake_src_install
-	einstalldocs
-
-	if use webui; then
-		newconfd "${FILESDIR}/${PN}.confd" "${PN}"
-		newinitd "${FILESDIR}/${PN}.initd" "${PN}"
-	fi
-}