net-misc/electron-cash: add 4.2.10

Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 158 insertions, 0 deletions

diff --git a/net-misc/electron-cash/Manifest b/net-misc/electron-cash/Manifest
index b4e99b7f9172..7d6de4e7a6ff 100644
--- a/net-misc/electron-cash/Manifest
+++ b/net-misc/electron-cash/Manifest
@@ -1 +1,2 @@
+DIST electron-cash-4.2.10.tar.gz 8023055 BLAKE2B e79c000f4278c323a8f14aa8d960c25c2971a8c5736e31a6f18f4b5faae11a8ff5339de3193e191c21373075bd6472570770d14262c9b5d41e3eca2b91e633d3 SHA512 f90a11f6a5d79024f982f8ab148c9c079049114bcb0c405da9f54b62620afbda462e074abde01bed7fa12d0090a842e393e24e66ff74031a87f0c79f6323895a
 DIST electron-cash-4.2.9.tar.gz 8023098 BLAKE2B 37a55e2161a8f7c2d9b11c1bc564d77ace84ad745be677bb41f07af2b8c18c223e6cf37c7df42dea170341f276babd8eda4bd9564e9069fc9623a059cc92f09b SHA512 e27dda4a4c8b81ad7b303652fdb2d893c3d53e76eb0f7e295753a7f92676c895ea8087e424a43bbb2d32db9a4f0e8c03b779cf9daf2ff8e51d4813a097ac9c6c
diff --git a/net-misc/electron-cash/electron-cash-4.2.10.ebuild b/net-misc/electron-cash/electron-cash-4.2.10.ebuild
new file mode 100644
index 000000000000..fc56ca7c306e
--- /dev/null
+++ b/net-misc/electron-cash/electron-cash-4.2.10.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+PYTHON_REQ_USE="ncurses?"
+
+inherit desktop distutils-r1 xdg-utils
+
+MY_P="Electron-Cash-${PV}"
+DESCRIPTION="Lightweight Bitcoin Cash client (BCH fork of Electrum)"
+HOMEPAGE="https://github.com/Electron-Cash/Electron-Cash"
+SRC_URI="https://github.com/Electron-Cash/Electron-Cash/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="amodem cli cosign digitalbitbox email ncurses qrcode +qt5 sync vkb
+	l10n_es l10n_ja l10n_pt l10n_zh-CN"
+RESTRICT+=" test"
+
+REQUIRED_USE="
+	|| ( cli ncurses qt5 )
+	amodem? ( qt5 )
+	cosign? ( qt5 )
+	digitalbitbox? ( qt5 )
+	email? ( qt5 )
+	qrcode? ( qt5 )
+	sync? ( qt5 )
+	vkb? ( qt5 )
+"
+
+RDEPEND="
+	dev-python/dnspython[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/jsonrpclib[${PYTHON_USEDEP}]
+	dev-python/pathvalidate[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/pyaes[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	net-libs/stem[${PYTHON_USEDEP}]
+	amodem? ( dev-python/amodem[${PYTHON_USEDEP}] )
+	qrcode? ( media-gfx/zbar[v4l] )
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	ncurses? ( dev-lang/python )
+	dev-libs/libsecp256k1
+"
+
+distutils_enable_tests pytest
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="RELEASE-NOTES"
+
+src_prepare() {
+	eapply "${FILESDIR}/3.3.6-no-user-root.patch"
+
+	# Prevent icon from being installed in the wrong location
+	sed -i '/icons/d' setup.py || die
+
+	if use qt5; then
+		pyrcc5 icons.qrc -o electroncash_gui/qt/icons_rc.py || die
+	else
+		sed "s|'electroncash_gui.qt',||" -i setup.py || die
+	fi
+
+	local wordlist=
+	for wordlist in  \
+		$(usex l10n_ja '' japanese) \
+		$(usex l10n_pt '' portuguese) \
+		$(usex l10n_es '' spanish) \
+		$(usex l10n_zh-CN '' chinese_simplified) \
+	; do
+		rm -f "electroncash/wordlist/${wordlist}.txt" || die
+		sed -i "/${wordlist}\\.txt/d" electroncash/mnemonic.py || die
+	done
+
+	# Remove unrequested GUI implementations:
+	local gui setup_py_gui
+	for gui in  \
+		$(usex cli      '' stdio)  \
+		$(usex qt5      '' qt   )  \
+		$(usex ncurses  '' text )  \
+	; do
+		rm electroncash_gui/"${gui}"* -r || die
+	done
+
+	# And install requested ones...
+	for gui in  \
+		$(usex qt5      qt   '')  \
+	; do
+		setup_py_gui="${setup_py_gui}'electrum_gui.${gui}',"
+	done
+
+	sed -i "s/'electrum_gui\\.qt',/${setup_py_gui}/" setup.py || die
+
+	local bestgui
+	if use qt5; then
+		bestgui=qt
+	elif use ncurses; then
+		bestgui=text
+	else
+		bestgui=stdio
+	fi
+	sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' "${PN}" || die
+
+	local plugin
+	# trezor requires python trezorlib module
+	# keepkey requires trezor
+	for plugin in  \
+		$(usex amodem          '' audio_modem          ) \
+		$(usex cosign          '' cosigner_pool        ) \
+		$(usex digitalbitbox   '' digitalbitbox        ) \
+		$(usex email           '' email_requests       ) \
+		hw_wallet \
+		ledger \
+		keepkey \
+		$(usex sync            '' labels               ) \
+		trezor  \
+		$(usex vkb             '' virtualkeyboard      ) \
+	; do
+		rm -r electroncash_plugins/"${plugin}"* || die
+		sed -i "/${plugin}/d" setup.py || die
+	done
+
+	eapply_user
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	doicon -s 128 icons/${PN}.png
+	distutils-r1_src_install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}