media-plugins/vdr-streamdev: version bump, minor fixes

readdy for vdr-2.4
fixed prepare/install phase depend by use-flags

Suggested-by: Martin Dummer <martin.dummer@gmx.net>
Closes: https://bugs.gentoo.org/703992
Package-Manager: Portage-2.3.83, Repoman-2.3.20
Signed-off-by: Joerg Bornkessel <hd_brummy@gentoo.org>

4 files changed, 83 insertions, 4 deletions

diff --git a/media-plugins/vdr-streamdev/Manifest b/media-plugins/vdr-streamdev/Manifest
index daf09a582a67..e6086445fdfe 100644
--- a/media-plugins/vdr-streamdev/Manifest
+++ b/media-plugins/vdr-streamdev/Manifest
@@ -1,2 +1,3 @@
 DIST vdr-plugin-streamdev-674bb5b331240de3ba2a8beb63a1276003e64e3e.tar.bz2 163096 BLAKE2B f451c435b24b69b0b09b5f2f041888ed3593ed7deee727a027672df9dd4d7c9183a68d40751ae5c12765037b4d5520f8ad824ead357b2a6597aaa15be7e573f5 SHA512 f9439a4c3dd453869f9cf3171ddb5e34c2a625d7873cb1648138e4b94715ec3acd8d3db69df5ae5bf1bc21f0401f9b12a126395b0f2696c129ee7725c1715902
+DIST vdr-plugin-streamdev-e2a9b979d3fb92967c7a6a8221e674eb7e55c813.tar.bz2 163403 BLAKE2B 4cacadc091ab8d28ccd4318eaf18aaef8f45e6caab86ef461d1b1047039ec921984ebad091d29420779982b5b37606defe5aa6c6828e8f28788886ba9839efea SHA512 e1eb69f62785178c06fa6700bd1b94ac12f2c58b1a7b8067312613279b59c5ef8157474e27863e8b2d0e47700f67fca7a61595c49809512e9e1efdb27c85eac8
 DIST vdr-streamdev-0.6.1.tgz 186546 BLAKE2B 7d5d92c8ec92e7a57e8e335bdbdf5c91bcbfcdc3ea96fe8154af7015f33d6f2822cf35681a8018cad5b19776199d90870b747bc0a551f42a7b0eedc94f040188 SHA512 bbe6231bd8e69e299c8d94173e7ed4b1f49e5b17b7bcadf2d1e827b5e8dd57c6b975c8c409fd44f252110099b3565a7d4d8c2f7d03636fc2d2e3580d0050d971
diff --git a/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1.ebuild b/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1.ebuild
index bdacdc2493dd..86fe10fda4b8 100644
--- a/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1.ebuild
+++ b/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
@@ -14,7 +14,7 @@ SRC_URI="mirror://vdr-developerorg/${VERSION}/${P}.tgz"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 x86"
-IUSE="client +server"
+IUSE="client server"
 
 DEPEND=">=media-video/vdr-1.7.25"
 RDEPEND="${DEPEND}"
diff --git a/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20160320.ebuild b/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20160320.ebuild
index 8e69d5831329..855928673f01 100644
--- a/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20160320.ebuild
+++ b/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20160320.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -14,7 +14,7 @@ SRC_URI="https://projects.vdr-developer.org/git/vdr-plugin-streamdev.git/snapsho
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
-IUSE="client +server"
+IUSE="client server"
 
 DEPEND=">=media-video/vdr-1.7.25"
 RDEPEND="${DEPEND}"
diff --git a/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20170930.ebuild b/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20170930.ebuild
new file mode 100644
index 000000000000..b5c3b4f0a9cc
--- /dev/null
+++ b/media-plugins/vdr-streamdev/vdr-streamdev-0.6.1_p20170930.ebuild
@@ -0,0 +1,78 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vdr-plugin-2
+
+GIT_VERSION="e2a9b979d3fb92967c7a6a8221e674eb7e55c813"
+
+DESCRIPTION="VDR Plugin: Client/Server and http streaming plugin"
+HOMEPAGE="https://projects.vdr-developer.org/projects/plg-streamdev"
+SRC_URI="https://projects.vdr-developer.org/git/vdr-plugin-streamdev.git/snapshot/vdr-plugin-streamdev-${GIT_VERSION}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="client server"
+REQUIRED_USE="|| ( client server )"
+
+DEPEND=">=media-video/vdr-2.3"
+RDEPEND="${DEPEND}"
+
+QA_FLAGS_IGNORED="
+	usr/lib/vdr/plugins/libvdr-streamdev-.*
+	usr/lib64/vdr/plugins/libvdr-streamdev-.*"
+S="${WORKDIR}/vdr-plugin-streamdev-${GIT_VERSION}"
+
+# vdr-plugin-2.eclass changes
+PO_SUBDIR="client server"
+
+src_prepare() {
+	# make detection in vdr-plugin-2.eclass for new Makefile handling happy
+	echo "# SOFILE" >> Makefile || die "modify Makefile failed"
+
+	# rm unneeded entry
+	sed -i Makefile -e "s:-I\$(VDRDIR)/include::" || die "modify Makefile failed"
+
+	vdr-plugin-2_src_prepare
+
+	for flag in client server; do
+		if ! use ${flag}; then
+			sed -i Makefile \
+				-e '/^.PHONY:/s/'${flag}'//' \
+				-e '/^.PHONY:/s/'install-${flag}'//' \
+				-e '/^all:/s/'${flag}'//' \
+				-e '/^install:/s/'install-${flag}'//' || die "modify Makefile failed"
+		fi
+	done
+
+	fix_vdr_libsi_include server/livestreamer.c
+}
+
+src_install() {
+	vdr-plugin-2_src_install
+
+	if use server; then
+		insinto /usr/share/vdr/streamdev
+		doins streamdev-server/externremux.sh
+
+		insinto /usr/share/vdr/rcscript
+		newins "${FILESDIR}"/rc-addon-0.6.0.sh plugin-streamdev-server.sh
+
+		newconfd "${FILESDIR}"/confd-0.6.0 vdr.streamdev-server
+
+		insinto /etc/vdr/plugins/streamdev-server
+		newins streamdev-server/streamdevhosts.conf streamdevhosts.conf
+		fowners vdr:vdr /etc/vdr -R
+	fi
+}
+
+pkg_postinst() {
+	vdr-plugin-2_pkg_postinst
+
+	if [[ -e "${EROOT}"/etc/vdr/plugins/streamdev/streamdevhosts.conf ]]; then
+		einfo "move config file to new config DIR ${EROOT}/etc/vdr/plugins/streamdev-server/"
+		mv "${EROOT}"/etc/vdr/plugins/streamdev/streamdevhosts.conf "${EROOT}"/etc/vdr/plugins/streamdev-server/streamdevhosts.conf
+	fi
+}