media-gfx/fontforge: bump to 20201107

Bug: https://bugs.gentoo.org/753788
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/media-gfx/fontforge/Manifest b/media-gfx/fontforge/Manifest
index d5e989988676..74c0099dc368 100644
--- a/media-gfx/fontforge/Manifest
+++ b/media-gfx/fontforge/Manifest
@@ -1 +1,2 @@
 DIST fontforge-20200314.tar.xz 13850076 BLAKE2B 5e6ae3b7940a5b3b08811abdfc9d151f231e6d457b219eb0c666e1b831db815b696f345eda0d4d423b7e340f56fca67205734ae19903b3815381080d34b5e95c SHA512 09f5dc93f87ca63668d72d108690604489d6b3cec7eedff1c07ad6d1ce5eae442ab60e79e71ae8b99e9808f3551011788025a86ffc3a9738518d99761d849975
+DIST fontforge-20201107.tar.xz 14163424 BLAKE2B 8ce9148eef6e5b7206ab5c70310ff36fac67c392117e3c0b28060803a54306bf21c179b62b98734e11253739eac29e2ea8bcf3014c09432bb3a0b2b0f3ec631a SHA512 cf9666395405ab02943f0160959f04251bd2a80e279a8f60431089ad19a4c5a232efd42097050ed9f6c1fb39d01488176262949fd81f5f0960fe853b497437dc
diff --git a/media-gfx/fontforge/fontforge-20201107.ebuild b/media-gfx/fontforge/fontforge-20201107.ebuild
new file mode 100644
index 000000000000..96f32a9698ba
--- /dev/null
+++ b/media-gfx/fontforge/fontforge-20201107.ebuild
@@ -0,0 +1,112 @@
+# Copyright 2004-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit python-single-r1 xdg cmake
+
+DESCRIPTION="postscript font editor and converter"
+HOMEPAGE="https://fontforge.org/"
+SRC_URI="https://github.com/fontforge/fontforge/releases/download/${PV}/fontforge-${PV}.tar.xz"
+
+LICENSE="BSD GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc truetype-debugger gif gtk jpeg png +python readline test tiff svg unicode woff2 X"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libltdl:0
+	dev-libs/libxml2:2=
+	>=media-libs/freetype-2.3.7:2=
+	gif? ( media-libs/giflib:0= )
+	jpeg? ( virtual/jpeg:0 )
+	png? ( media-libs/libpng:0= )
+	tiff? ( media-libs/tiff:0= )
+	truetype-debugger? ( >=media-libs/freetype-2.3.8:2[fontforge,-bindist(-)] )
+	gtk? ( >=x11-libs/gtk+-3.10:3 )
+	!gtk? (
+		X? (
+			>=x11-libs/cairo-1.6:0=
+			>=x11-libs/pango-1.10:0=[X]
+			x11-libs/libX11:0=
+			x11-libs/libXi:0=
+		)
+	)
+	python? ( ${PYTHON_DEPS} )
+	readline? ( sys-libs/readline:0= )
+	unicode? ( media-libs/libuninameslist:0= )
+	woff2? ( media-libs/woff2:0= )
+"
+DEPEND="${RDEPEND}
+	!gtk? ( X? ( x11-base/xorg-proto ) )
+"
+BDEPEND="
+	sys-devel/gettext
+	doc? ( >=dev-python/sphinx-2 )
+	python? ( ${PYTHON_DEPS} )
+	test? ( ${RDEPEND} )
+"
+
+PATCHES=(
+	"${FILESDIR}"/fontforge-doc-no-warn-error.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOCS=$(usex doc ON OFF)
+		-DENABLE_LIBGIF=$(usex gif ON OFF)
+		-DENABLE_LIBJPEG=$(usex jpeg ON OFF)
+		-DENABLE_LIBPNG=$(usex png ON OFF)
+		-DENABLE_LIBREADLINE=$(usex readline ON OFF)
+		-DENABLE_LIBSPIRO=OFF # No package in Gentoo
+		-DENABLE_LIBTIFF=$(usex tiff ON OFF)
+		-DENABLE_LIBUNINAMESLIST=$(usex unicode ON OFF)
+		-DENABLE_MAINTAINER_TOOLS=OFF
+		-DENABLE_PYTHON_EXTENSION=$(usex python ON OFF)
+		-DENABLE_PYTHON_SCRIPTING=$(usex python ON OFF)
+		-DENABLE_TILE_PATH=ON
+		-DENABLE_WOFF2=$(usex woff2 ON OFF)
+	)
+
+	if use gtk || use X; then
+		mycmakeargs+=(
+			-DENABLE_GUI=ON
+			# Prefer GTK over X11 if both USE flage are enabled
+			-DENABLE_X11=$(usex gtk OFF ON)
+		)
+	else
+		mycmakeargs+=( -DENABLE_GUI=OFF )
+	fi
+
+	if use python; then
+		python_setup
+		mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
+	fi
+
+	if use truetype-debugger ; then
+		local ft2="${ESYSROOT}/usr/include/freetype2"
+		local ft2i="${ft2}/internal4fontforge"
+		mycmakeargs+=(
+			-DENABLE_FREETYPE_DEBUGGER="${ft2}"
+			-DFreeTypeSource_INCLUDE_DIRS="${ft2};${ft2i}/include;${ft2i}/include/freetype;${ft2i}/src/truetype"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	docompress -x /usr/share/doc/${PF}/html
+	einstalldocs
+	find "${ED}" -name '*.la' -type f -delete || die
+}