proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 62 insertions, 0 deletions

diff --git a/mail-client/cone/cone-0.90.ebuild b/mail-client/cone/cone-0.90.ebuild
new file mode 100644
index 000000000000..dba487ad4377
--- /dev/null
+++ b/mail-client/cone/cone-0.90.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+inherit eutils autotools
+
+DESCRIPTION="CONE: COnsole News reader and Emailer"
+HOMEPAGE="http://www.courier-mta.org/cone/"
+SRC_URI="mirror://sourceforge/courier/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ppc ~sparc x86"
+IUSE="crypt fam gnutls idn ipv6 ldap spell"
+
+RDEPEND=">=dev-libs/openssl-0.9.6
+	dev-libs/libxml2
+	sys-libs/ncurses
+	crypt? ( >=app-crypt/gnupg-1.0.4 )
+	fam? ( virtual/fam )
+	gnutls? ( net-libs/gnutls )
+	idn? ( net-dns/libidn )
+	ipv6? ( net-dns/libidn )
+	ldap? ( net-nds/openldap )
+	spell? ( app-text/aspell )"
+DEPEND="${RDEPEND}
+	dev-lang/perl"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.84.20100819-aspell-automagic.patch \
+		"${FILESDIR}"/${PN}-0.86-skip-rfc2045-test.patch
+
+	# move local macro to m4 and run eautoreconf
+	mkdir "${S}/m4"
+	sed -n -e '/# AC_PROG_SYSCONFTOOL/,+33 p' "${S}"/aclocal.m4 > \
+		m4/sysconftool.m4 || die
+	sed -i -e '/^SUBDIRS/i ACLOCAL_AMFLAGS = -I m4' "${S}"/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+	if use spell ; then
+	   myconf="--with-spellcheck=aspell"
+	else
+	   myconf="--with-spellcheck=none"
+	fi
+
+	econf \
+		${myconf} \
+		$(use_with ldap ldapaddressbook) \
+		$(use_with gnutls) \
+		$(use_with idn libidn) \
+		$(use_with ipv6)
+}
+
+src_install() {
+	default
+	emake DESTDIR="${D}" install-configure
+}