kde-plasma/plasma-firewall: 5.26.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 9478ce265c1e..defaf8035887 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.25.5.tar.xz 357380 BLAKE2B 37dcd280306a4b7674a78ce8a74f01ea804a136174725d228370427567b851dff6eeed01aaa687014d565c19694908f0f9aba4f811da8c7d8d2208b6d0250581 SHA512 b6059e732f34af49263ff0beecb9f11894420166a60ef0ebdce38fff9bb472c1c6d058f4ae6d3cae8194c5b6efe127971e6057564e887317250a4691df73e1e0
 DIST plasma-firewall-5.26.1.tar.xz 358352 BLAKE2B b03c636c69ba87ed67bdc0fb82f163df268aef342769f9b7d69019f5b4c0d5963f4208ca89b8baac39fbcc0e1954e4edcf8d160879054dc0e0d2c34fca5c2115 SHA512 1ad061e2405f140ed7a653a3bd4106f61c14d36667fd5ad9e057d56128552a054c441009e1db2949383fe454611b5dec2e408479708eb2dbe044eb08f8497916
+DIST plasma-firewall-5.26.2.tar.xz 358396 BLAKE2B d27614fd6161fb24cea54e96ff451b6c2cfad6b3be45bc532fd0e5075a406b34f311a33a56e62ab170b47066b980553cc9155adffd55fa9273b1768efdcfe086 SHA512 8446207445aa0987446c10ef65d2f4470c873e863e980933513b3a30a949398cf6bfef918f13962f900d262781aa0f8bcef28d7d6f10c047ee666adfeaf967d6
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.26.2.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.26.2.ebuild
new file mode 100644
index 000000000000..3538edc241a0
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.26.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}