gnome-extra/nemo: 4.4.2 version bump

Update nemo to 4.4.2. Switch to EAPI=7 and clean
up eclass usage and dependencies. Tracker support
dropped upstream.

Bug: https://bugs.gentoo.org/718316
Bug: https://bugs.gentoo.org/704532
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 91 insertions, 0 deletions

diff --git a/gnome-extra/nemo/Manifest b/gnome-extra/nemo/Manifest
index c0f873adf1cb..940f72a4afa7 100644
--- a/gnome-extra/nemo/Manifest
+++ b/gnome-extra/nemo/Manifest
@@ -1 +1,2 @@
 DIST nemo-4.0.6.tar.gz 1449313 BLAKE2B 0d80e23a503c34e52f126635a7b3df54f7f0d336a637f14e11ac8e1d252a4b7bd43173c362ea0f24602fc4eceb71c97d651ddec2f2922d70c32518fbc8d15424 SHA512 87006f345317b37093daed1081880a4c28eb84438b9c43f9b62211824306074969e5e21df57cfc5fa163d66d16bcf7ba6c26674e27353cfd8a91cf2bfe82099f
+DIST nemo-4.4.2.tar.gz 1462269 BLAKE2B 365cd98a05c0c4aa1c86a3e7a565904852bd02d92ace8593043ae8a58f5b9d3eda71e8b0d329a177ed59c0d8f1330ae61f5bcc6671110e82bbd9baad84faa9f0 SHA512 b951c401f93d04061a0ef0accc810ecc7f0487617f089960ab58886a6ca6ecd0af3a98c47e9a620a4d6f8f530a11af9cae20903d089177e69bfa12f9ca31ec5c
diff --git a/gnome-extra/nemo/metadata.xml b/gnome-extra/nemo/metadata.xml
index b3526b807770..519e96b93408 100644
--- a/gnome-extra/nemo/metadata.xml
+++ b/gnome-extra/nemo/metadata.xml
@@ -5,6 +5,14 @@
 		<email>cinnamon@gentoo.org</email>
 		<name>Cinnamon Project</name>
 	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>sparky@bluefang-logic.com</email>
+		<name>Matthew Turnbull</name>
+	</maintainer>
 	<use>
 		<flag name="packagekit">Use packagekit to search for programs to open unknown file types</flag>
 		<flag name="tracker">Add support for <pkg>app-misc/tracker</pkg> search</flag>
diff --git a/gnome-extra/nemo/nemo-4.4.2.ebuild b/gnome-extra/nemo/nemo-4.4.2.ebuild
new file mode 100644
index 000000000000..ae981c8d835e
--- /dev/null
+++ b/gnome-extra/nemo/nemo-4.4.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson gnome2-utils python-single-r1 virtualx xdg
+
+DESCRIPTION="A file manager for Cinnamon, forked from Nautilus"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/"
+SRC_URI="https://github.com/linuxmint/nemo/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc exif +nls selinux xmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT=test
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.37.3:2[dbus]
+	>=dev-libs/gobject-introspection-0.6.4:=
+	>=gnome-extra/cinnamon-desktop-4.4:0=
+	>=x11-libs/pango-1.28.3
+	>=x11-libs/gtk+-3.9.10:3[introspection]
+	>=dev-libs/libxml2-2.7.8:2
+
+	gnome-base/dconf:0=
+	>=x11-libs/libnotify-0.7:=
+	x11-libs/libX11
+	>=x11-libs/xapps-1.4.0
+
+	exif? ( >=media-libs/libexif-0.6.20:= )
+	xmp? ( >=media-libs/exempi-2.2.0:= )
+	selinux? ( sys-libs/libselinux )
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+	nls? ( >=gnome-extra/cinnamon-translations-4.4 )
+	$(python_gen_cond_dep '
+		dev-python/polib[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+"
+PDEPEND=">=gnome-base/gvfs-0.1.2"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.31.0
+	>=dev-util/intltool-0.40.1
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	xdg_environment_reset
+	default
+	python_fix_shebang files/usr/share/nemo/actions
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif)
+		$(meson_use xmp)
+		$(meson_use selinux)
+		$(meson_use doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}