gnome-base/gnome-keyring: Bump to 46.2

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35360
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/gnome-base/gnome-keyring/Manifest b/gnome-base/gnome-keyring/Manifest
index d554a568c123..8bff71ca483b 100644
--- a/gnome-base/gnome-keyring/Manifest
+++ b/gnome-base/gnome-keyring/Manifest
@@ -1 +1,2 @@
 DIST gnome-keyring-42.1.tar.xz 1346284 BLAKE2B ff6093cc16c649cda1e6cc2848c2198a502d8aa20a56f0a4dca00550e99f18820028427a7ec3979b6871648a7931da19fced3210558d5ca3de47983b7c94452d SHA512 560dc409c21768dcbdf42151986a5bbbfb9a092d2c36295cf76bd603cdf9650fa80670631c7fb8b3e1822bed6a1f55c34b2170a1419ce45fbe8ca08c7eaf3a57
+DIST gnome-keyring-46.2.tar.xz 1359500 BLAKE2B 47dad5b1eab387e600016828c99d7c829f509e9929e0e06d6427f6c84053050be1e79c4fb369caa1cdfc862e20677a518155b1a5496a64e118f461e81b60edcd SHA512 4229ca0606bdd1b84a3c737288df7f1fc1f8715734e3001964babd882201c3d818deabb3a7662dbf9b67316f03b234de84da3128fb991a500ef8305c2f962ba2
diff --git a/gnome-base/gnome-keyring/gnome-keyring-46.2.ebuild b/gnome-base/gnome-keyring/gnome-keyring-46.2.ebuild
new file mode 100644
index 000000000000..922f67d84aed
--- /dev/null
+++ b/gnome-base/gnome-keyring/gnome-keyring-46.2.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome2 pam python-any-r1 virtualx
+
+DESCRIPTION="Password and keyring managing daemon"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="pam selinux +ssh-agent systemd test valgrind"
+RESTRICT="!test? ( test )"
+
+# Replace gkd gpg-agent with pinentry[gnome-keyring] one, bug #547456
+RDEPEND="
+	>=app-crypt/gcr-3.27.90:0=[gtk]
+	>=app-crypt/gnupg-2.0.28:=
+	>=app-eselect/eselect-pinentry-0.5
+	app-misc/ca-certificates
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	pam? ( sys-libs/pam )
+	selinux? ( sec-policy/selinux-gnome )
+	ssh-agent? ( virtual/openssh )
+"
+DEPEND="
+	${RDEPEND}
+	valgrind? ( dev-debug/valgrind )
+"
+BDEPEND="
+	>=app-eselect/eselect-pinentry-0.5
+	app-text/docbook-xml-dtd:4.3
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid CFLAGS with debug enabled
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--without-libcap-ng \
+		$(use_enable pam) \
+		$(use_with pam pam-dir $(getpam_mod_dir)) \
+		$(use_enable selinux) \
+		$(use_enable ssh-agent) \
+		$(use_with systemd) \
+		$(use_enable valgrind) \
+		--enable-doc
+}
+
+src_test() {
+	# Needs dbus-run-session to not get:
+	# ERROR: test-dbus-search process failed: -6
+	"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/schema" || die
+	GSETTINGS_SCHEMA_DIR="${S}/schema" virtx dbus-run-session emake check
+}
+
+pkg_postinst() {
+	# cap_ipc_lock only needed if building --with-libcap-ng, but that breaks with glib-2.70
+	# Never install as suid root, this breaks dbus activation, see bug #513870
+	gnome2_pkg_postinst
+
+	if ! [[ $(eselect pinentry show | grep "pinentry-gnome3") ]] ; then
+		ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+		ewarn " # eselect pinentry set pinentry-gnome3"
+	fi
+}