games-engines/scummvm: Bump to 2.6.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 154 insertions, 7 deletions

diff --git a/games-engines/scummvm/Manifest b/games-engines/scummvm/Manifest
index abe9f6272320..3660a6b7cce8 100644
--- a/games-engines/scummvm/Manifest
+++ b/games-engines/scummvm/Manifest
@@ -1,2 +1,3 @@
 DIST scummvm-2.5.1.tar.xz 132828412 BLAKE2B 08fb2fa6cbeec3c1ec24a9b660aab4344f0dbcf4c42655392315aef0ce78105b2a669ef9c82fc09bc389856e592e4e5249d84512b288e7d790914d5caee3972d SHA512 5e5aaf247e26434dd1594547a3066dce6f52e12370532b8bff09ae22149d697f6d3ab0a94b5c1cf578b2b8cba32d1cd6e5dc30fe0cd6266c8f2b23cba13d7d03
 DIST scummvm-2.6.0.tar.xz 141331920 BLAKE2B 38cdce3e9b7954347d3ba05946c607aa5a62aa8fa1c2145030c1667632a4da43afd3f14ed19ebaf664bbf521610b2cfccc739c82dae95650572bfab81495cb80 SHA512 6bb2b22f9b11a8de2eaa48c520d63579f4907fa49d8b02d58702ece86945b38ea911376f5ae0dc6f3b6ed794ff32ca51fbf690e341401b4a03276b32e9bd7b69
+DIST scummvm-2.6.1.tar.xz 141354456 BLAKE2B b54001a53b3c899831745c94b1bf6020b462dfd49f6de35a609a6977846e7d036ee6c323c888c88379f4b6149dad31a1af5a38ae8d5231303dbba6a0ba97bb2f SHA512 984e35683ec4fa6a0715a20027d471ff432a2da060caf1b28557e42ae7b2b5c3b32c3ef4f3c1fb0ac9bcde69d01f789b3054fe9b0ddb0fe9fadbee462c1afcc5
diff --git a/games-engines/scummvm/scummvm-2.6.1.ebuild b/games-engines/scummvm/scummvm-2.6.1.ebuild
new file mode 100644
index 000000000000..d678e3432dbb
--- /dev/null
+++ b/games-engines/scummvm/scummvm-2.6.1.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit desktop flag-o-matic toolchain-funcs xdg
+
+DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
+HOMEPAGE="https://www.scummvm.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/scummvm/scummvm"
+else
+	SRC_URI="https://downloads.scummvm.org/frs/scummvm/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+	S=${WORKDIR}/${P/_/}
+fi
+
+LICENSE="GPL-2+ LGPL-2.1 BSD GPL-3-with-font-exception"
+SLOT="0"
+IUSE="
+	a52 aac alsa debug flac fluidsynth fribidi gif +gtk jpeg lua mpeg2
+	mp3 +net opengl png sndio speech theora truetype unsupported vorbis
+	zlib
+"
+RESTRICT="test"  # it only looks like there's a test there #77507
+
+DEPEND="
+	>=media-libs/libsdl2-2.0.0[sound,joystick,video]
+	a52? ( media-libs/a52dec )
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:= )
+	fluidsynth? ( media-sound/fluidsynth:= )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib )
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gtk+:3
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	mp3? ( media-libs/libmad )
+	mpeg2? ( media-libs/libmpeg2 )
+	net? (
+		media-libs/sdl2-net
+		net-misc/curl
+	)
+	opengl? (
+		|| (
+			virtual/opengl
+			media-libs/mesa[gles2]
+			media-libs/mesa[gles1]
+		)
+	)
+	png? ( media-libs/libpng:0 )
+	sndio? ( media-sound/sndio:= )
+	speech? ( app-accessibility/speech-dispatcher )
+	truetype? ( media-libs/freetype:2 )
+	theora? ( media-libs/libtheora )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	app-arch/xz-utils
+	truetype? ( virtual/pkgconfig )
+	x86? ( dev-lang/nasm )
+"
+
+src_prepare() {
+	default
+
+	# -g isn't needed for nasm here
+	sed -i \
+		-e '/NASMFLAGS/ s/-g//' \
+		configure || die
+	sed -i \
+		-e '/INSTALL.*doc/d' \
+		-e '/INSTALL.*\/pixmaps/d' \
+		-e 's/-s //' \
+		ports.mk || die
+}
+
+src_configure() {
+	use x86 && append-ldflags -Wl,-z,noexecstack
+	tc-export STRINGS
+
+	local myconf=(
+		--backend=sdl
+		--host=${CHOST}
+		--enable-verbose-build
+		--prefix="${EPREFIX}/usr"
+		--libdir="${EPREFIX}/usr/$(get_libdir)"
+		--opengl-mode=$(usex opengl auto none)
+		--with-sdl-prefix="${EPREFIX}/usr"
+		$(use_enable a52)
+		$(use_enable aac faad)
+		$(use_enable alsa)
+		$(use_enable debug)
+		$(use_enable !debug release-mode)
+		$(use_enable flac)
+		$(usex fluidsynth '' --disable-fluidsynth)
+		$(use_enable fribidi)
+		$(use_enable gif)
+		$(use_enable gtk)
+		$(use_enable jpeg)
+		$(use_enable lua)
+		$(use_enable mp3 mad)
+		$(use_enable mpeg2)
+		$(use_enable net libcurl)
+		$(use_enable net sdlnet)
+		$(use_enable png)
+		$(use_enable sndio)
+		$(use_enable speech tts)
+		$(use_enable theora theoradec)
+		$(use_enable truetype freetype2)
+		$(usex unsupported --enable-all-engines '')
+		$(use_enable vorbis)
+		$(use_enable zlib)
+		$(use_enable x86 nasm)
+	)
+	echo "configure ${myconf[@]}"
+	# not an autoconf script, so don't call econf
+	SDL_CONFIG="sdl2-config" \
+	./configure "${myconf[@]}" ${EXTRA_ECONF} || die
+}
+
+src_compile() {
+	emake \
+		AR="$(tc-getAR) cru" \
+		RANLIB="$(tc-getRANLIB)"
+}
+
+src_install() {
+	default
+	doicon -s scalable icons/scummvm.svg
+}
diff --git a/games-engines/scummvm/scummvm-9999.ebuild b/games-engines/scummvm/scummvm-9999.ebuild
index 4e32d433ef29..d678e3432dbb 100644
--- a/games-engines/scummvm/scummvm-9999.ebuild
+++ b/games-engines/scummvm/scummvm-9999.ebuild
@@ -13,15 +13,19 @@ if [[ ${PV} == *9999* ]]; then
 else
 	SRC_URI="https://downloads.scummvm.org/frs/scummvm/${PV}/${P}.tar.xz"
 	KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~x86"
-	S="${WORKDIR}/${PN}-${P}"
+	S=${WORKDIR}/${P/_/}
 fi
 
 LICENSE="GPL-2+ LGPL-2.1 BSD GPL-3-with-font-exception"
 SLOT="0"
-IUSE="a52 aac alsa debug flac fluidsynth fribidi gif +gtk jpeg lua mpeg2 mp3 +net opengl png sndio speech theora truetype unsupported vorbis zlib"
+IUSE="
+	a52 aac alsa debug flac fluidsynth fribidi gif +gtk jpeg lua mpeg2
+	mp3 +net opengl png sndio speech theora truetype unsupported vorbis
+	zlib
+"
 RESTRICT="test"  # it only looks like there's a test there #77507
 
-RDEPEND="
+DEPEND="
 	>=media-libs/libsdl2-2.0.0[sound,joystick,video]
 	a52? ( media-libs/a52dec )
 	aac? ( media-libs/faad2 )
@@ -59,15 +63,15 @@ RDEPEND="
 	)
 	zlib? ( sys-libs/zlib:= )
 "
-DEPEND="${RDEPEND}"
+RDEPEND="
+	${DEPEND}
+"
 BDEPEND="
 	app-arch/xz-utils
 	truetype? ( virtual/pkgconfig )
 	x86? ( dev-lang/nasm )
 "
 
-S="${WORKDIR}/${P/_/}"
-
 src_prepare() {
 	default
 
@@ -121,7 +125,7 @@ src_configure() {
 		$(use_enable x86 nasm)
 	)
 	echo "configure ${myconf[@]}"
-	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
+	# not an autoconf script, so don't call econf
 	SDL_CONFIG="sdl2-config" \
 	./configure "${myconf[@]}" ${EXTRA_ECONF} || die
 }