dev-util/devhelp: Version bump to 40.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-util/devhelp/Manifest b/dev-util/devhelp/Manifest
index 4e832e78d2c5..b3f2105aa476 100644
--- a/dev-util/devhelp/Manifest
+++ b/dev-util/devhelp/Manifest
@@ -1 +1,2 @@
 DIST devhelp-40.0.tar.xz 318076 BLAKE2B 05345f422e0ec906855c139306020165277daefea2c85229092be57c98f96459c33ab0fdf847a7135fa1b329c76edea71f7da0342c6673a828efe26298d26bdf SHA512 b8dd5fbb12558845f7f5794dad56ef0ffc1dbd60d5a6a28029dc8acea241e8deb1b68cd0abe9d620a512931a1c5f6db12fc594cd4597758c8d4904fb64e6ade7
+DIST devhelp-40.1.tar.xz 318172 BLAKE2B 83f71b66538b700790961e3dd3c7c7a75199f499a1fb32eb01e62fd5d11e72ae4e860bcfab2615bd4d417d5c57b89dad7eb2f1de4930e39e544d42b57a193b97 SHA512 4c541db9a2222dce4064f401c1d0a9f3233e2dbab17206358dfcce360286f69698248d08172fb236a692b125d8cd3a5bb76b6377b01b52c3d096fa4528400acd
diff --git a/dev-util/devhelp/devhelp-40.1.ebuild b/dev-util/devhelp/devhelp-40.1.ebuild
new file mode 100644
index 000000000000..fc32178168aa
--- /dev/null
+++ b/dev-util/devhelp/devhelp-40.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-3+ CC-BY-SA-4.0"
+SLOT="0/3-6" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~amd64 ~arm ~ppc64 ~sparc ~x86"
+IUSE="+gedit gtk-doc +introspection"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/glib-2.64:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=net-libs/webkit-gtk-2.24:4[introspection?]
+	>=gui-libs/amtk-5.0:5
+	gnome-base/gsettings-desktop-schemas
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			app-editors/gedit[introspection(+),python,${PYTHON_SINGLE_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	dev-util/itstool
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/40.0-optional-introspection.patch
+)
+
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dflatpak_build=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dplugin_emacs=true
+		$(meson_use gedit plugin_gedit)
+		-Dplugin_vim=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	use gedit && python_optimize "${ED}"/usr/$(get_libdir)/gedit/plugins
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}