dev-qt/linguist: png support in qtgui is required

Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Davide Pesavento <pesa@gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-qt/linguist/linguist-5.15.2-r11.ebuild b/dev-qt/linguist/linguist-5.15.2-r11.ebuild
new file mode 100644
index 000000000000..d381188a7d98
--- /dev/null
+++ b/dev-qt/linguist/linguist-5.15.2-r11.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_COMMIT=33693a928986006d79c1ee743733cde5966ac402
+QT5_MODULE="qttools"
+inherit desktop qt5-build xdg-utils
+
+DESCRIPTION="Graphical tool for translating Qt applications"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
+fi
+
+IUSE=""
+
+DEPEND="
+	=dev-qt/designer-${QT5_PV}*
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*:5=[png]
+	=dev-qt/qtprintsupport-${QT5_PV}*
+	=dev-qt/qtwidgets-${QT5_PV}*
+	=dev-qt/qtxml-${QT5_PV}*
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/linguist/linguist
+)
+
+src_install() {
+	qt5-build_src_install
+
+	local size
+	for size in 16 32 48 64 128; do
+		newicon -s ${size} src/linguist/linguist/images/icons/linguist-${size}-32.png linguist.png
+	done
+	make_desktop_entry "${QT5_BINDIR}"/linguist 'Qt 5 Linguist' linguist 'Qt;Development;Translation'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	xdg_icon_cache_update
+}