dev-python/imageio: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 104 deletions

diff --git a/dev-python/imageio/Manifest b/dev-python/imageio/Manifest
index c6d5412ec021..32063c0ec732 100644
--- a/dev-python/imageio/Manifest
+++ b/dev-python/imageio/Manifest
@@ -1,3 +1,2 @@
-DIST imageio-2.35.1.gh.tar.gz 415944 BLAKE2B 303cc3ab288b184fdbd8b5a1e3cb47308bd96e818793245d84f4bb3fb55f117fb61ae49df80aada8aceb128172d3b47e48fe0a47823a0734847a98983f2ec80c SHA512 7aa486c23179a798b3801a4ea7d71d2a4f81f53a02dcd0f83537bb3b3ce617b02882bb970e45bc390c106b8d7c62822a736f898ff21dac4951963f2cbc899fc4
 DIST imageio-2.36.0.gh.tar.gz 415793 BLAKE2B 2b382290ab41a8b265629695c484eac887f33900d2b1a2a1e35f5db9ebc776242f7325e4c50055ab500f98067f1a27d083cd6aee9c0cf65dfe3e18c1d62336c2 SHA512 8d59633d31211e0510e8790e0d052b0c0d8912cc49a187c7d846ab62c2210b8f1851b63c83a0daf6123fc905b351ea0b51883746f6dcb83939975f51b913f63c
 DIST imageio-test_images-1121036015c70cdbb3015e5c5ba0aaaf7d3d6021.gh.tar.gz 195497374 BLAKE2B 0083212fd63c196dc2e721bff8f89c177b6741317b6b1c6ae9d00a8dd5fb6366efa3f01b9bffafafac7177cfdaa4d700077a2bad42ada735f5553e97f651c4ad SHA512 1bb1f36a069bfaa0d0ffe5258534e02e49237fc6ce85fe3d3648650130165abc9b3d5ff0e7e5861ee1d94add00d4258575f9c2f8556debecf597bdaa5499efe0
diff --git a/dev-python/imageio/imageio-2.35.1.ebuild b/dev-python/imageio/imageio-2.35.1.ebuild
deleted file mode 100644
index 9f86e40a6cdb..000000000000
--- a/dev-python/imageio/imageio-2.35.1.ebuild
+++ /dev/null
@@ -1,103 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit distutils-r1
-
-TEST_IMAGES_COMMIT=1121036015c70cdbb3015e5c5ba0aaaf7d3d6021
-DESCRIPTION="Python library for reading and writing image data"
-HOMEPAGE="
-	https://imageio.readthedocs.io/en/stable/
-	https://github.com/imageio/imageio/
-	https://pypi.org/project/imageio/
-"
-SRC_URI="
-	https://github.com/imageio/imageio/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-	test? (
-		https://github.com/imageio/test_images/archive/${TEST_IMAGES_COMMIT}.tar.gz
-			-> imageio-test_images-${TEST_IMAGES_COMMIT}.gh.tar.gz
-	)
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-
-RDEPEND="
-	>=dev-python/numpy-1.20.0[${PYTHON_USEDEP}]
-	>=dev-python/pillow-8.3.2[${PYTHON_USEDEP}]
-	media-libs/freeimage
-"
-BDEPEND="
-	test? (
-		>=dev-python/imageio-ffmpeg-0.4.9-r1[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		dev-python/tifffile[${PYTHON_USEDEP}]
-		|| (
-			media-video/ffmpeg[openh264]
-			media-video/ffmpeg[x264]
-		)
-	)
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	local PATCHES=(
-		# block silently downloading vulnerable libraries from the Internet
-		"${FILESDIR}/imageio-2.22.0-block-download.patch"
-	)
-
-	if use test; then
-		mv "${WORKDIR}/test_images-${TEST_IMAGES_COMMIT}" .test_images || die
-		# upstream tries to update the image cache, and invalidates it
-		# if "git pull" fails
-		sed -i -e 's:git pull:true:' tests/conftest.py || die
-		# ffmpeg tests expect it there
-		mkdir -p "${HOME}/.imageio/images" || die
-		cp .test_images/cockatoo.mp4 "${HOME}/.imageio/images" || die
-	fi
-
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# uses fsspec to grab prebuilt .so from GitHub, sigh
-		tests/test_freeimage.py
-	)
-
-	local EPYTEST_DESELECT=(
-		# Note: upstream has a needs_internet marker but it is also
-		# used to mark tests that require test_images checkout that we
-		# supply
-
-		# Tries to download ffmpeg binary ?!
-		tests/test_ffmpeg.py::test_get_exe_installed
-		# blocked by our patch
-		tests/test_core.py::test_fetching
-		tests/test_core.py::test_request
-		# Internet
-		tests/test_bsdf.py::test_from_url
-		tests/test_core.py::test_mvolread_out_of_bytes
-		tests/test_core.py::test_request_read_sources
-		tests/test_pillow.py::test_gif_first_p_frame
-		tests/test_pillow.py::test_png_remote
-		tests/test_pillow.py::test_webp_remote
-		tests/test_pillow_legacy.py::test_png_remote
-		tests/test_swf.py::test_read_from_url
-		# requires pillow-heif, also possibly Internet
-		tests/test_pillow.py::test_avif_remote
-		tests/test_pillow.py::test_heif_remote
-		# not important, requires random system libs
-		tests/test_core.py::test_findlib2
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest
-}