dev-libs/m17n-lib: new upstream release

Package-Manager: Portage-2.3.6, Repoman-2.3.1

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-libs/m17n-lib/Manifest b/dev-libs/m17n-lib/Manifest
index 0eda6c4df8f4..0e54516857c2 100644
--- a/dev-libs/m17n-lib/Manifest
+++ b/dev-libs/m17n-lib/Manifest
@@ -1,3 +1,4 @@
 DIST m17n-lib-1.5.2.tar.gz 997592 SHA256 389cc05194e9a1f9e58b186c3fcd60d7fee2a6f627c3ea8f9c944d69983721f1 SHA512 899959ad7d6b32b7ec0a97eca5abf2a3a4e9d44d81b5157bc974b17544db4e59550bc04b0b2d46371dc57f64c7e0aa70ebb7d473ade3a762f40acf19ac19b072 WHIRLPOOL 9483d3fcc97aad78b44dd228e8c800e5147cc7c7758e72b87e4875960abe0f8d5b34ab669ec858da4d1792c1c3b58dc3669f4ced9bf8f151924f0d44dbf7b3e0
 DIST m17n-lib-1.6.3.tar.gz 1033048 SHA256 ff5ebe09572a5e6d4a376783a78d4355f0b17a71fbaf8b01978230be7eef735e SHA512 66177e5be17e330230d31bfff8a3cc7415ad79f9bfaf8f4c4baea02f1f19bf2d3628210c697a9b14d07dcb9bac8ca256e6c5102cbaae65876bf49aa2150cfd80 WHIRLPOOL ac337d68c4cfd0f9c331ded71a16c4d86f2d4c655a59f17da92fc8a80ed6f420af97ceb2ff071d556aaee0cf73baae9736faed32aaa58538d59a44f27a981c53
 DIST m17n-lib-1.6.4.tar.gz 1034422 SHA256 0370fda16bce321acad96b623dbbead0d797d86f5d5fa43d0cde8ff3b01555a4 SHA512 751f22efdaf4fb3e23d17ca07e20c65c59d60ff4f90a384bd9a8e9e8b01503d87c76cfc4c3c9717d8549a08c705b1c444939816a7eb07ca77b029b4f457f58c3 WHIRLPOOL d5bdfbb072a557f8e37307a4de56a9d2eb24c637afb885f294ab1970d8ca916bc53354ae7ca0fb4c6eaf445c955b60b79a0718c4e72af533a844d770a7b36a8c
+DIST m17n-lib-1.7.0.tar.gz 1063169 SHA256 8eb853e1e0c86a70a09871f3264f950e5d62bba98960b3ffcde11511c138db83 SHA512 26fc1be02a5e487a2fa5f2f63d991f3c745aa1b78e20d931fe4b265125266501cc8d402aa3cb5c1b71a7d4c0f7a0bf5b2c3b17ec5f4f8e0f5ee3052ad4e205b7 WHIRLPOOL ea677f51af7eae80cffb8fcf3e09acb73d6483391a9e776de860137ad19c27c5472394367f4181a63e43891c3514a4b59dc635cfd83ab0e545560f368144878b
diff --git a/dev-libs/m17n-lib/m17n-lib-1.7.0.ebuild b/dev-libs/m17n-lib/m17n-lib-1.7.0.ebuild
new file mode 100644
index 000000000000..fc89235d9280
--- /dev/null
+++ b/dev-libs/m17n-lib/m17n-lib-1.7.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools
+
+DESCRIPTION="Multilingual Library for Unix/Linux"
+HOMEPAGE="https://savannah.nongnu.org/projects/m17n"
+SRC_URI="mirror://nongnu/m17n/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="X anthy athena bidi fontconfig gd libotf libxml2 spell xft"
+
+RDEPEND="~dev-db/m17n-db-${PV}
+	X? (
+		x11-libs/libX11
+		athena? ( x11-libs/libXaw )
+		bidi? ( dev-libs/fribidi )
+		fontconfig? ( media-libs/fontconfig )
+		gd? ( media-libs/gd[png] )
+		libotf? ( dev-libs/libotf )
+		xft? (
+			media-libs/freetype
+			x11-libs/libXft
+		)
+	)
+	anthy? ( app-i18n/anthy )
+	libxml2? ( dev-libs/libxml2 )
+	spell? ( app-text/aspell )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-configure.patch
+	"${FILESDIR}"/${PN}-gui.patch
+	"${FILESDIR}"/${PN}-ispell.patch
+	"${FILESDIR}"/${PN}-parallel-make.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+	# workaround for parallel install
+	sed -i "/^install-module/s/:/: install-libLTLIBRARIES/" src/Makefile.in
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with anthy)
+		$(use_with libxml2)
+		$(use_with spell ispell)
+	)
+	if use X; then
+		myconf+=(
+			$(use_with athena)
+			$(use_with bidi fribidi)
+			$(use_with fontconfig)
+			$(use_with xft freetype)
+			$(use_with gd)
+			--with-gui
+			$(use_with libotf)
+			--with-x
+			$(use_with xft)
+		)
+	else
+		myconf+=(
+			--without-athena
+			--without-fontconfig
+			--without-freetype
+			--without-fribidi
+			--without-gd
+			--without-gui
+			--without-libotf
+			--without-x
+			--without-xft
+		)
+	fi
+
+	econf "${myconf[@]}"
+}