dev-libs/intel-compute-runtime: add 24.35.30872.25

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index ed1ad8bd41c3..c3ab9350e4b4 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1 +1,2 @@
 DIST intel-compute-runtime-24.35.30872.22.tar.gz 7375152 BLAKE2B a7c65663ff06983de5a3476fed479f6eced77c4a47bbbd49528bf149356d1fffcf55055eeb338995046a4ae271f1d515bc9732a042fcf66e2acab308e8b26fdf SHA512 800cad432be1f5619f95cf345c58ec9a58a907f95253f5f1bea1cce27cccf72948f94a327c8f0d7b251b45ae83d4b99a820e0eccd7b1e729979fd86eeaa8fc14
+DIST intel-compute-runtime-24.35.30872.25.tar.gz 7375680 BLAKE2B 8aede769b46ecdb2eb49346bc87c1e58fbefa382e80419a301b00197fbdc977f62b001e7670a912a28c736aafc59e60d45a4c4d3e61331d6001307c184d3a4b8 SHA512 4e09f432f1f3a7f8c3b9a7bbd6981f2b26a837fc6f6b4459d21bb51fcce94a3c95726d23fb77be2664c7fbdf4dd270e1ec21af1bc815e718a5df865e8bbdac03
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-24.35.30872.25.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-24.35.30872.25.ebuild
new file mode 100644
index 000000000000..79089e9ed29b
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-24.35.30872.25.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND="
+	>=dev-util/intel-graphics-compiler-1.0.17657.8
+	>=media-libs/gmmlib-22.5.2:=
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/intel-metrics-discovery:=
+	>=dev-libs/intel-metrics-library-1.0.173:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-system-controller-0.9.3:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.17.42:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Filtered for two reasons:
+	# 1) https://github.com/intel/compute-runtime/issues/528
+	# 2) bug #930199
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO_DISABLE_LTO="ON"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}