app-portage/portage-utils-0.94.4: version bump for #880867

Closes: https://bugs.gentoo.org/880867
Signed-off-by: Fabian Groffen <grobian@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/app-portage/portage-utils/Manifest b/app-portage/portage-utils/Manifest
index 6350de83d263..095df425a8d1 100644
--- a/app-portage/portage-utils/Manifest
+++ b/app-portage/portage-utils/Manifest
@@ -1,2 +1,3 @@
 DIST portage-utils-0.94.1.tar.xz 1871688 BLAKE2B bec5ddd514b397c157c3b1bff70d61730f15804a6751f56eb69c4030a35fc6a6b11fa1e2bde94332772660f02bf9428623210733ae9e2f1290f29aa3b31a1813 SHA512 29fdb4093997eb95703d407da6b00305c949f0a00ae3aa5cfb2c47b66bddc59e034fae114663b40b611f906332066b648018aa4e5bc1b935e61a64f4b4bf1088
 DIST portage-utils-0.94.3.tar.xz 1804720 BLAKE2B b0239a26d878db6dd73c9ee54f586526f8812921775126ef74afbe089186fdc5ca7197847e204c6ecbf9d79b6e2a6173cb0c39d4a26653ed0db2d7f9b10e88c5 SHA512 bf8fcccc26bb985bf7664f6ab0227a5251c3f918199de0c4e4c95b7107eb72eee367d1d524b5d9608b3c7eea9b1fae789456390cbb0d375297b807bb98644e01
+DIST portage-utils-0.94.4.tar.xz 1804252 BLAKE2B 4bdb3dca331eeeaeca34b949aa0228d81df71888fa7cb07f878958939f7820f6887ebb43f0a89d8ed8d787c152a631a731bc53f30c8241ca2530ee9420fea1e2 SHA512 d59a09c9b2dd4de8ed320a5b1c943a1d5dcdef41a057fbfeb00ed136e2ba87375d4562861de5b0e44bad986916d0f58487f3d93deaeb44e96385535d85d74217
diff --git a/app-portage/portage-utils/portage-utils-0.94.4.ebuild b/app-portage/portage-utils/portage-utils-0.94.4.ebuild
new file mode 100644
index 000000000000..b07e43f8a485
--- /dev/null
+++ b/app-portage/portage-utils/portage-utils-0.94.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Small and fast Portage helper tools written in C"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Portage-utils"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/portage-utils.git"
+else
+	SRC_URI="https://dev.gentoo.org/~grobian/distfiles/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="openmp +qmanifest +qtegrity static"
+
+RDEPEND="
+	qmanifest? (
+		!static? (
+			app-crypt/gpgme:=
+			app-crypt/libb2:=
+			dev-libs/openssl:=
+			sys-libs/zlib:=
+		)
+	)
+	qtegrity? (
+		!static? (
+			dev-libs/openssl:=
+		)
+	)"
+DEPEND="${RDEPEND}
+	qmanifest? (
+		static? (
+			app-crypt/gpgme[static-libs]
+			app-crypt/libb2[static-libs]
+			dev-libs/openssl[static-libs]
+			sys-libs/zlib[static-libs]
+		)
+	)
+	qtegrity? (
+		static? (
+			dev-libs/openssl[static-libs]
+		)
+	)"
+BDEPEND="virtual/pkgconfig"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+
+	econf \
+		--disable-maintainer-mode \
+		--with-eprefix="${EPREFIX}" \
+		$(use_enable qmanifest) \
+		$(use_enable qtegrity) \
+		$(use_enable openmp)
+}