mate-base/mate: 1.12 buump, add gtk3, from project repo, support new themes

Package-Manager: portage-2.3.0

3 files changed, 169 insertions, 0 deletions

diff --git a/mate-base/mate/mate-1.10.0-r3.ebuild b/mate-base/mate/mate-1.10.0-r3.ebuild
new file mode 100644
index 000000000000..99097a2a025a
--- /dev/null
+++ b/mate-base/mate/mate-1.10.0-r3.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit versionator
+
+MATE_MV="$(get_version_component_range 1-2)"
+
+SRC_URI=""
+DESCRIPTION="Meta ebuild for MATE, a traditional desktop environment"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="metapackage"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+base -bluetooth +notification +themes +extras"
+
+S="${WORKDIR}"
+
+RDEPEND="
+	=mate-base/mate-desktop-${MATE_MV}*:0
+	=mate-base/mate-menus-${MATE_MV}*:0
+	=mate-base/mate-panel-${MATE_MV}*:0
+	=mate-base/mate-session-manager-${MATE_MV}*:0
+	=mate-base/mate-settings-daemon-${MATE_MV}*:0
+	=x11-wm/marco-${MATE_MV}*:0
+	base? (
+		=mate-base/caja-${MATE_MV}*:0
+		=mate-base/mate-applets-meta-${MATE_MV}*:0
+		=mate-base/mate-control-center-${MATE_MV}*:0
+		=mate-extra/mate-media-${MATE_MV}*:0
+		=x11-misc/mozo-${MATE_MV}*:0
+		=x11-terms/mate-terminal-${MATE_MV}*:0
+	)
+	bluetooth? ( net-wireless/blueman:0 )
+	themes? (
+		=x11-themes/mate-backgrounds-${MATE_MV}*:0
+		=x11-themes/mate-icon-theme-${MATE_MV}*:0
+		>=x11-themes/mate-themes-meta-3:0
+	)
+	extras? (
+		=app-arch/engrampa-${MATE_MV}*:0
+		=app-editors/pluma-${MATE_MV}*:0
+		=app-text/atril-${MATE_MV}*:0
+		gnome-extra/gnome-calculator:0
+		=mate-extra/caja-extensions-${MATE_MV}*:0
+		=mate-extra/mate-netbook-${MATE_MV}*:0
+		=mate-extra/mate-power-manager-${MATE_MV}*:0
+		=mate-extra/mate-screensaver-${MATE_MV}*:0
+		=mate-extra/mate-system-monitor-${MATE_MV}*:0
+		=mate-extra/mate-utils-${MATE_MV}*:0
+		=media-gfx/eom-${MATE_MV}*:0
+		=net-analyzer/mate-netspeed-${MATE_MV}*:0
+		sys-apps/gnome-disk-utility:0
+	)
+"
+
+PDEPEND="
+	notification? ( x11-misc/mate-notification-daemon )
+	virtual/notification-daemon:0"
+
+pkg_postinst() {
+	elog "For installation, usage and troubleshooting details regarding MATE;"
+	elog "read more about it at Gentoo Wiki: https://wiki.gentoo.org/wiki/MATE"
+	elog ""
+	if ! has_version x11-misc/mate-notification-daemon; then
+		elog "If you experience any issues with notifications, please try using"
+		elog "x11-misc/mate-notification-daemon instead your currently installed daemon"
+		elog ""
+	fi
+	elog "MATE 1.10 had some packages renamed, replaced and/or dropped; for more"
+	elog "details, see http://mate-desktop.org/blog/2015-06-11-mate-1-10-released/"
+	elog ""
+	elog "Some packages that are not included in this meta-package but may be of interest:"
+	elog "		mate-extra/caja-dropbox"
+	elog "		mate-extra/mate-user-share"
+}
diff --git a/mate-base/mate/mate-1.12-r1.ebuild b/mate-base/mate/mate-1.12-r1.ebuild
new file mode 100644
index 000000000000..fd289cc9cc07
--- /dev/null
+++ b/mate-base/mate/mate-1.12-r1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+if [[ ${PV} == 9999 ]]; then
+	MATE_BRANCH=9999
+	MATE_THEMES_V=9999
+else
+	inherit versionator
+	MATE_BRANCH="$(get_version_component_range 1-2)"
+	MATE_THEMES_V=3
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+SRC_URI=""
+DESCRIPTION="Meta ebuild for MATE, a traditional desktop environment"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="metapackage"
+
+SLOT="0"
+IUSE="+base -bluetooth gtk3 help +notification +themes +extras"
+
+S="${WORKDIR}"
+
+RDEPEND="
+	=mate-base/mate-desktop-${MATE_BRANCH}*:0[gtk3(-)?]
+	=mate-base/mate-menus-${MATE_BRANCH}*:0
+	=mate-base/mate-panel-${MATE_BRANCH}*:0[gtk3(-)?]
+	=mate-base/mate-session-manager-${MATE_BRANCH}*:0[gtk3(-)?]
+	=mate-base/mate-settings-daemon-${MATE_BRANCH}*:0[gtk3(-)?]
+	=x11-wm/marco-${MATE_BRANCH}*:0[gtk3(-)?]
+	base? (
+		=mate-base/caja-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-base/mate-applets-meta-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-base/mate-control-center-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-extra/mate-media-${MATE_BRANCH}*:0[gtk3(-)?]
+		=x11-misc/mozo-${MATE_BRANCH}*:0[gtk3(-)?]
+		=x11-terms/mate-terminal-${MATE_BRANCH}*:0[gtk3(-)?]
+	)
+	bluetooth? ( net-wireless/blueman:0 )
+	themes? (
+		=x11-themes/mate-backgrounds-${MATE_BRANCH}*:0
+		=x11-themes/mate-icon-theme-${MATE_BRANCH}*:0
+		>=x11-themes/mate-themes-meta-${MATE_THEMES_V}:0
+	)
+	extras? (
+		=app-arch/engrampa-${MATE_BRANCH}*:0[gtk3(-)?]
+		=app-editors/pluma-${MATE_BRANCH}*:0[gtk3(-)?]
+		=app-text/atril-${MATE_BRANCH}*:0[gtk3(-)?]
+		gnome-extra/gnome-calculator:0
+		=mate-extra/caja-extensions-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-extra/mate-netbook-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-extra/mate-power-manager-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-extra/mate-screensaver-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-extra/mate-system-monitor-${MATE_BRANCH}*:0[gtk3(-)?]
+		=mate-extra/mate-utils-${MATE_BRANCH}*:0[gtk3(-)?]
+		=media-gfx/eom-${MATE_BRANCH}*:0[gtk3(-)?]
+		=net-analyzer/mate-netspeed-${MATE_BRANCH}*:0[gtk3(-)?]
+		sys-apps/gnome-disk-utility:0
+	)
+	help? (
+		gnome-extra/yelp:0
+		=mate-extra/mate-user-guide-${MATE_BRANCH}*:0
+	)
+"
+
+PDEPEND="
+	notification? ( =x11-misc/mate-notification-daemon-${MATE_BRANCH}*:0[gtk3(-)?] )
+	virtual/notification-daemon:0"
+
+pkg_postinst() {
+	elog "For installation, usage and troubleshooting details regarding MATE;"
+	elog "read more about it at Gentoo Wiki: https://wiki.gentoo.org/wiki/MATE"
+	elog ""
+	if ! has_version x11-misc/mate-notification-daemon; then
+		elog "If you experience any issues with notifications, please try using"
+		elog "x11-misc/mate-notification-daemon instead your currently installed daemon"
+		elog ""
+	fi
+	elog "Some packages that are not included in this meta-package but may be of interest:"
+	elog "		mate-extra/caja-dropbox"
+	elog "		mate-extra/mate-user-share"
+}
diff --git a/mate-base/mate/metadata.xml b/mate-base/mate/metadata.xml
index d617e6093745..9f44953b0c50 100644
--- a/mate-base/mate/metadata.xml
+++ b/mate-base/mate/metadata.xml
@@ -10,6 +10,7 @@
 			recommended for the most common usage; for example, this installs
 			the file manager. Disable this and other USE flags if you want a
 			more minimal MATE Desktop.</flag>
+		<flag name="gtk3">Build all of MATE DE with GTK+3 instead of GTK+2</flag>
 		<flag name="notification">Force notification daemon to default to MATE's
 			notification daemon. Enabled by default. Disable if it causes conflicts
 			with other installed desktop environments.</flag>
@@ -21,5 +22,7 @@
 			applications. Disable this if you plan to use your own non-MATE
 			Desktop alternatives or a custom mixture of MATE and non-MATE
 			packages.</flag>
+		<flag name="help">Install <pkg>gnome-extra/yelp</pkg> to handle in application
+			help menus and documentation browsing</flag>
 	</use>
 </pkgmetadata>