app-emacs/magit: drop libegit2 dependency

Closes: https://bugs.gentoo.org/910381
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

3 files changed, 62 insertions, 34 deletions

diff --git a/app-emacs/magit/magit-3.3.0-r1.ebuild b/app-emacs/magit/magit-3.3.0-r1.ebuild
new file mode 100644
index 000000000000..f5457ac3eebe
--- /dev/null
+++ b/app-emacs/magit/magit-3.3.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="A Git porcelain inside Emacs"
+HOMEPAGE="https://magit.vc/
+	https://github.com/magit/magit/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/magit/magit.git"
+else
+	SRC_URI="https://github.com/magit/magit/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="amd64 ~arm ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux"
+fi
+S="${S}/lisp"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+DOCS=( ../README.md ../Documentation/AUTHORS.md ../Documentation/RelNotes )
+ELISP_TEXINFO="../Documentation/*.texi"
+SITEFILE="50${PN}-gentoo.el"
+
+RDEPEND="
+	>=app-emacs/dash-2.19.1
+	>=app-emacs/transient-0.3.6
+	>=app-emacs/with-editor-3.0.5
+"
+BDEPEND="
+	${RDEPEND}
+	sys-apps/texinfo
+"
+RDEPEND+="
+	>=dev-vcs/git-2.0.0
+"
+
+src_prepare() {
+	default
+
+	echo "(setq magit-version \"${PV}\")" > magit-version.el || die
+}
+
+pkg_postinst() {
+	elisp_pkg_postinst
+
+	einfo "magit version 3.3.0 dropped necessity of the app-emacs/libegit2 package"
+	einfo "magit after 3.3.0 can now use the git executable directly,"
+	einfo "if you need the libegit backend, then please add app-emacs/libegit2 to @world"
+}
diff --git a/app-emacs/magit/magit-3.3.0.ebuild b/app-emacs/magit/magit-3.3.0.ebuild
deleted file mode 100644
index 87684a463d06..000000000000
--- a/app-emacs/magit/magit-3.3.0.ebuild
+++ /dev/null
@@ -1,33 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit elisp
-
-DESCRIPTION="A Git porcelain inside Emacs"
-HOMEPAGE="https://magit.vc/"
-SRC_URI="https://github.com/magit/magit/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux"
-
-S="${WORKDIR}/${P}/lisp"
-SITEFILE="50${PN}-gentoo.el"
-ELISP_TEXINFO="../Documentation/*.texi"
-DOCS="../README.md ../Documentation/AUTHORS.md ../Documentation/RelNotes/*"
-
-DEPEND="
-	>=app-emacs/dash-2.19.1
-	app-emacs/libegit2
-	>=app-emacs/transient-0.3.6
-	>=app-emacs/with-editor-3.0.5
-"
-RDEPEND="${DEPEND} >=dev-vcs/git-2.0.0"
-DEPEND="${DEPEND} sys-apps/texinfo"
-
-src_prepare() {
-	default
-	echo "(setq magit-version \"${PV}\")" > magit-version.el || die
-}
diff --git a/app-emacs/magit/magit-9999.ebuild b/app-emacs/magit/magit-9999.ebuild
index 031034b86493..d9d3068acc4b 100644
--- a/app-emacs/magit/magit-9999.ebuild
+++ b/app-emacs/magit/magit-9999.ebuild
@@ -30,7 +30,6 @@ RDEPEND="
 	>=app-emacs/dash-2.19.1
 	>=app-emacs/transient-0.3.6
 	>=app-emacs/with-editor-3.0.5
-	app-emacs/libegit2
 "
 BDEPEND="
 	${RDEPEND}
@@ -45,3 +44,11 @@ src_prepare() {
 
 	echo "(setq magit-version \"${PV}\")" > magit-version.el || die
 }
+
+pkg_postinst() {
+	elisp_pkg_postinst
+
+	einfo "magit version 3.3.0 dropped necessity of the app-emacs/libegit2 package"
+	einfo "magit after 3.3.0 can now use the git executable directly,"
+	einfo "if you need the libegit backend, then please add app-emacs/libegit2 to @world"
+}