kde-plasma/discover: drop 5.27.5

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 1 insertions, 89 deletions

diff --git a/kde-plasma/discover/discover-5.27.5.ebuild b/kde-plasma/discover/discover-5.27.5.ebuild
deleted file mode 100644
index 52fe9d6d5df5..000000000000
--- a/kde-plasma/discover/discover-5.27.5.ebuild
+++ /dev/null
@@ -1,89 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_TEST="true"
-KFMIN=5.102.0
-QTMIN=5.15.7
-VIRTUALX_REQUIRED="test"
-inherit ecm plasma.kde.org
-
-DESCRIPTION="KDE Plasma resources management GUI"
-HOMEPAGE="https://userbase.kde.org/Discover"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="+firmware flatpak telemetry webengine"
-
-# libmarkdown (app-text/discount) only used in PackageKitBackend
-DEPEND="
-	>=dev-libs/appstream-0.15.3:=
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/attica-${KFMIN}:5
-	>=kde-frameworks/kcmutils-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kdeclarative-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kidletime-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kirigami-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/purpose-${KFMIN}:5
-	firmware? ( >=sys-apps/fwupd-1.5.0 )
-	flatpak? ( sys-apps/flatpak )
-	telemetry? ( dev-libs/kuserfeedback:5 )
-	webengine? ( >=dev-qt/qtwebview-${QTMIN}:5 )
-"
-RDEPEND="${DEPEND}
-	>=dev-qt/qtquickcontrols2-${QTMIN}:5
-"
-BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
-
-PATCHES=( "${FILESDIR}/${PN}-5.25.90-tests-optional.patch" )
-
-src_prepare() {
-	ecm_src_prepare
-	# we don't need it with PackageKitBackend off
-	ecm_punt_kf_module Archive
-	# we don't do anything with this
-	sed -e "s/^pkg_check_modules.*RpmOstree/#&/" \
-		-e "s/^pkg_check_modules.*Ostree/#&/" \
-		-i CMakeLists.txt || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
-		-DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
-		-DWITH_KCM=OFF
-		-DBUILD_FlatpakBackend=$(usex flatpak)
-		-DBUILD_FwupdBackend=$(usex firmware)
-		$(cmake_use_find_package telemetry KUserFeedback)
-		$(cmake_use_find_package webengine Qt5WebView)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	# bug 686392: needs network connection
-	local myctestargs=(
-		-E "(knsbackendtest|flatpaktest)"
-	)
-
-	ecm_src_test
-}
diff --git a/kde-plasma/discover/metadata.xml b/kde-plasma/discover/metadata.xml
index dd2b69f93957..13c683e94092 100644
--- a/kde-plasma/discover/metadata.xml
+++ b/kde-plasma/discover/metadata.xml
@@ -12,6 +12,7 @@
 	<use>
 		<flag name="firmware">Enable support for firmware upgrades using <pkg>sys-apps/fwupd</pkg></flag>
 		<flag name="flatpak">Enable support for flatpak repositories using <pkg>sys-apps/flatpak</pkg></flag>
+		<flag name="snap">Enable support for snap packages using <pkg>app-containers/snapd</pkg></flag>
 		<flag name="webengine">Enable webflow support using <pkg>dev-qt/qtwebview</pkg> and <pkg>dev-qt/qtwebengine</pkg> instead of default URL handler</flag>
 	</use>
 </pkgmetadata>