app-dicts/gwaei: Port to EAPI 7

Closes: https://bugs.gentoo.org/742056
Package-Manager: Portage-3.0.7, Repoman-3.0.1
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 22 insertions, 27 deletions

diff --git a/app-dicts/gwaei/gwaei-3.6.2.ebuild b/app-dicts/gwaei/gwaei-3.6.2.ebuild
index 760d43ab9b63..045d9d6ad1f2 100644
--- a/app-dicts/gwaei/gwaei-3.6.2.ebuild
+++ b/app-dicts/gwaei/gwaei-3.6.2.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="4"
+EAPI=7
 
-inherit gnome2-utils eutils
+inherit gnome2-utils
 
 DESCRIPTION="Japanese-English Dictionary for GNOME"
 HOMEPAGE="http://gwaei.sourceforge.net/"
@@ -12,10 +12,11 @@ SRC_URI="mirror://sourceforge/gwaei/${P}.tar.xz"
 LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="gtk hunspell nls test mecab"
+IUSE="gtk hunspell nls mecab test"
 RESTRICT="!test? ( test )"
 
-RDEPEND=">=net-misc/curl-7.20.0
+RDEPEND="
+	>=net-misc/curl-7.20.0
 	>=dev-libs/glib-2.31
 	gtk? (
 		x11-libs/gtk+:3
@@ -25,50 +26,44 @@ RDEPEND=">=net-misc/curl-7.20.0
 	nls? ( virtual/libintl )
 	mecab? ( app-text/mecab )"
 DEPEND="${RDEPEND}
-	test? (
-		app-text/docbook-xml-dtd:4.1.2
-		app-text/scrollkeeper-dtd
-	)
 	gtk? (
 		x11-themes/gnome-icon-theme-symbolic
 		>=app-text/gnome-doc-utils-0.14.0
-	)
-	nls? ( >=sys-devel/gettext-0.17 )
+	)"
+BDEPEND="
 	app-text/rarian
 	dev-util/intltool
-	virtual/pkgconfig"
+	virtual/pkgconfig
+	nls? ( >=sys-devel/gettext-0.17 )
+	test? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/scrollkeeper-dtd
+	)"
 
 src_configure() {
 	econf \
+		--disable-static \
 		$(use_with gtk gnome) \
 		$(use_enable nls) \
 		$(use_with hunspell) \
-		$(use_with mecab) \
-		--disable-static \
-		--docdir=/usr/share/doc/${PF}
+		$(use_with mecab)
 }
 
 src_install() {
-	emake DESTDIR="${D}" install
-	find "${D}" -name '*.la' -delete
+	default
 
-	dodoc AUTHORS README
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
 }
 
 pkg_preinst() {
-	if use gtk ; then
-		gnome2_schemas_savelist
-	fi
+	use gtk && gnome2_schemas_savelist
 }
 
 pkg_postinst() {
-	if use gtk ; then
-		gnome2_schemas_update
-	fi
+	use gtk && gnome2_schemas_update
 }
 
 pkg_postrm() {
-	if use gtk ; then
-		gnome2_schemas_update
-	fi
+	use gtk && gnome2_schemas_update
 }