kde-apps/konsolepart: Install missing konsolepart.desktop file

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/kde-apps/konsolepart/konsolepart-23.08.5-r1.ebuild b/kde-apps/konsolepart/konsolepart-23.08.5-r1.ebuild
new file mode 100644
index 000000000000..87cd86cd4d14
--- /dev/null
+++ b/kde-apps/konsolepart/konsolepart-23.08.5-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+KDE_ORG_NAME="konsole"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE's terminal emulator kpart for use by konsole and other applications"
+HOMEPAGE="https://apps.kde.org/konsole/ https://konsole.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="amd64 arm64 ~loong ~ppc64 ~riscv x86"
+IUSE=""
+
+DEPEND="
+	dev-libs/icu:=
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-apps/konsole:5
+"
+
+PATCHES=( "${FILESDIR}/konsole-23.08.1-drop-unused-X11-dep.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=OFF
+		-DENABLE_PLUGIN_SSHMANAGER=OFF
+		-DENABLE_PLUGIN_QUICKCOMMANDS=OFF
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	rm -r "${ED}"/{etc,usr/bin} \
+		"${ED}"/usr/share/{applications,doc,help,kconf_update,kglobalaccel,kio} \
+		"${ED}"/usr/share/{knsrcfiles,knotifications5,konsole,locale,qlogging-categories5,zsh} \
+		"${ED}"/usr/$(get_libdir)/kconf_update_bin || die
+}