blob: 7e6220c83bf83231f1f95332e3dffb77a1cb9d4d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=5.249.0
QTMIN=6.6.0
inherit ecm gear.kde.org optfeature
DESCRIPTION="Image viewer by KDE"
HOMEPAGE="https://apps.kde.org/gwenview/ https://userbase.kde.org/Gwenview"
LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
SLOT="6"
KEYWORDS=""
IUSE="activities fits +mpris raw semantic-desktop share X"
# requires running environment
RESTRICT="test"
# slot op: includes qpa/qplatformnativeinterface.h
# TODO: When Qt6 version available: >=media-libs/kimageannotator-0.5.0, media-libs/kcolorpicker
COMMON_DEPEND="
dev-libs/wayland
>=dev-qt/qtbase-${QTMIN}:6=[gui,widgets]
>=dev-qt/qtsvg-${QTMIN}:6
>=dev-qt/qtwayland-${QTMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
media-gfx/exiv2:=
media-libs/lcms:2
media-libs/libjpeg-turbo:=
media-libs/libpng:0=
>=media-libs/phonon-4.12.0[qt6]
media-libs/tiff:=
activities? ( kde-plasma/plasma-activities:6 )
fits? ( sci-libs/cfitsio )
mpris? ( >=dev-qt/qtbase-${QTMIN}:6[dbus] )
raw? ( >=kde-apps/libkdcraw-${PVCUT}:6 )
semantic-desktop? (
>=kde-frameworks/baloo-${KFMIN}:6
>=kde-frameworks/kfilemetadata-${KFMIN}:6
)
share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
X? ( x11-libs/libX11 )
"
DEPEND="${COMMON_DEPEND}
dev-libs/wayland-protocols
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
>=kde-frameworks/kwindowsystem-${KFMIN}:6
"
RDEPEND="${COMMON_DEPEND}
>=dev-qt/qtimageformats-${QTMIN}:6
>=kde-frameworks/kimageformats-${KFMIN}:6
"
BDEPEND="
>=dev-qt/qtwayland-${QTMIN}:6
dev-util/wayland-scanner
"
src_prepare() {
ecm_src_prepare
if ! use mpris; then
# FIXME: upstream a better solution
sed -e "/set(HAVE_QTDBUS/s/\${Qt6DBus_FOUND}/0/" -i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package activities PlasmaActivities)
$(cmake_use_find_package fits CFitsio)
$(cmake_use_find_package raw KF6KDcraw)
-DGWENVIEW_SEMANTICINFO_BACKEND=$(usex semantic-desktop Baloo None)
$(cmake_use_find_package share KF6Purpose)
-DWITHOUT_X11=$(usex !X)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "SVG support" "kde-apps/svgpart:${SLOT}"
fi
ecm_pkg_postinst
}
|
GitWeb