Initial port of the layman-8888 ebuild to overlord-9999

4 files changed, 136 insertions, 0 deletions

diff --git a/app-portage/overlord/ChangeLog b/app-portage/overlord/ChangeLog
new file mode 100644
index 0000000..f27ad69
--- /dev/null
+++ b/app-portage/overlord/ChangeLog
@@ -0,0 +1,9 @@
+# ChangeLog for app-portage/layman
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header:                                                                                                   Exp $
+
+*overlord-9999 (03 Feb 2011)
+
+    03 Feb 2011; Brian Dolbec <brian.dolbec@gmail.com>  +overlord-9999.ebuild:
+    initial copy/edit of the layman-8888.ebuild for the project development
+    version.
diff --git a/app-portage/overlord/Manifest b/app-portage/overlord/Manifest
new file mode 100644
index 0000000..593c154
--- /dev/null
+++ b/app-portage/overlord/Manifest
@@ -0,0 +1,3 @@
+EBUILD overlord-9999.ebuild 2803 RMD160 30e20cd25c3b865878a679c91ba82e5a3cdedfa6 SHA1 7580cae30e7586fb9b11a185844a81973198ae0e SHA256 31729e90e0fdccf3349ac37503faa7bd75cb8058f4034431edc1096f56ad1945
+MISC ChangeLog 419 RMD160 7b368473ce4787df672a3eeb9f910e751a1797f8 SHA1 4ede2010df55206b37af0870c3d9ba389655dfe3 SHA256 e294940047b0079f16d9b87a3d642918748242710e4adf6ab76f21dd708e53fe
+MISC metadata.xml 787 RMD160 8eb69e7a49c273da69a9e6e6b514c0ed2f9890e2 SHA1 24e072a2d591f3b5e3733e85b0a5d5b91c7eef24 SHA256 a555029640c0b859e1d9a593d865b2f4c6126b2a57c6d31883e13fa55fdc7187
diff --git a/app-portage/overlord/metadata.xml b/app-portage/overlord/metadata.xml
new file mode 100644
index 0000000..70da95e
--- /dev/null
+++ b/app-portage/overlord/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>tools-portage</herd>
+<longdescription lang='en'>This is a development version used development of it's api's</longdescription>
+<maintainer>
+  <email>brian.dolbec@gmail.com</email>
+  <name>Brian Dolbec (dol-sen)</name>
+  <description>This is an experimental version used to develop the new api.</description>
+</maintainer>
+<use>
+  <flag name='bazaar'>Support <pkg>dev-vcs/bzr</pkg> based overlays</flag>
+  <flag name='darcs'>Support <pkg>dev-vcs/darcs</pkg> based overlays</flag>
+  <flag name='git'>Support <pkg>dev-vcs/git</pkg> based overlays</flag>
+  <flag name='mercurial'>Support <pkg>dev-vcs/mercurial</pkg> based overlays</flag>
+</use>
+</pkgmetadata>
diff --git a/app-portage/overlord/overlord-9999.ebuild b/app-portage/overlord/overlord-9999.ebuild
new file mode 100644
index 0000000..b57aa85
--- /dev/null
+++ b/app-portage/overlord/overlord-9999.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header:                                                                                       Exp $
+
+EAPI="2"
+PYTHON_DEPEND="2:2.5"
+SUPPORT_PYTHON_ABIS="1"
+EGIT_BRANCH="master"
+
+inherit eutils distutils git
+
+DESCRIPTION="An experimental development version of overlord, a python script for retrieving gentoo overlays."
+HOMEPAGE="http://dev.gentooexperimental.org/~dol-sen/"
+SRC_URI=""
+EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/overlord.git"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="bazaar cvs darcs git mercurial subversion test"
+
+COMMON_DEPS="dev-lang/python[xml]"
+DEPEND="${COMMON_DEPS}
+	test? ( dev-vcs/subversion )
+	app-text/xmlto"
+RDEPEND="${COMMON_DEPS}
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)"
+RESTRICT_PYTHON_ABIS="2.4 3.*"
+
+pkg_setup() {
+	if ! has_version dev-vcs/subversion; then
+		ewarn "You do not have dev-vcs/subversion installed!"
+		ewarn "While overlord does not exactly depend on this"
+		ewarn "version control system you should note that"
+		ewarn "most available overlays are offered via"
+		ewarn "dev-vcs/subversion. If you do not install it"
+		ewarn "you will be unable to use these overlays."
+		ewarn
+	fi
+}
+
+src_test() {
+	testing() {
+		for suite in layman/tests/{dtest,external}.py ; do
+			PYTHONPATH="." "$(PYTHON)" ${suite} \
+					|| die "test suite '${suite}' failed"
+		done
+	}
+	python_execute_function testing
+}
+
+src_compile() {
+	distutils_src_compile
+	emake -C doc || die "emake -C doc failed"
+}
+
+src_install() {
+	distutils_src_install
+
+	dodir /etc/overlord
+
+	cp etc/overlord.cfg "${D}"/etc/overlord/
+
+	doman doc/overlord.8
+	dohtml doc/overlord.8.html
+
+	keepdir /var/lib/layman
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+
+	einfo "You are now ready to add overlays into your system."
+	einfo
+	einfo "  lord -L"
+	einfo
+	einfo "will display a list of available overlays."
+	einfo
+	elog  "Select an overlay and add it using"
+	elog
+	elog  "  lord -a overlay-name"
+	elog
+	elog  "If this is the very first overlay you add with overlord or layman,"
+	elog  "you need to append the following statement to your"
+	elog  "/etc/make.conf file:"
+	elog
+	elog  "  source /var/lib/layman/make.conf"
+	elog
+	elog  "If you modify the 'storage' parameter in the overlord"
+	elog  "configuration file (/etc/overlord/overlord.cfg) you will"
+	elog  "need to adapt the path given above to the new storage"
+	elog  "directory."
+	elog
+	ewarn "Please add the 'source' statement to make.conf only AFTER "
+	ewarn "you added your first overlay. Otherwise portage will fail."
+	epause 5
+}