dev-vcs/hub/hub-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hub/hub-1.10.6.ebuild,v 1.1 2013/05/31 23:14:44 ottxor Exp $

EAPI=5

inherit bash-completion-r1 git-r3 readme.gentoo

DESCRIPTION="command-line wrapper for git that makes you better at GitHub"
HOMEPAGE="http://defunkt.io/hub/"
SRC_URI=""
EGIT_REPO_URI="https://github.com/github/hub.git"

LICENSE="MIT"
SLOT="0"
KEYWORDS=""
IUSE="test"

RDEPEND="dev-vcs/git"
DEPEND="
	dev-lang/go
	test? (
		app-misc/tmux
		dev-util/cucumber
		dev-ruby/bundler
		)"

DOC_CONTENTS="You may want to add 'alias git=hub' to your .{csh,bash}rc"

src_compile() {
	bash ./script/build || die
}

src_test() {
	bash ./script/test || die
}

src_install() {
	dobin ${PN}

	readme.gentoo_create_doc

	doman man/${PN}.1

	insinto /usr/share/${PN}/
	doins -r git-hooks

	# Broken with autoloader
	# https://github.com/github/hub/issues/592
	#newbashcomp etc/hub.bash_completion.sh ${PN}

	insinto /usr/share/zsh/site-functions
	newins etc/hub.zsh_completion ${PN}
}