Version bump; update DEPEND to use recent versions of kBuild and gsoap

svn path=/trunk/; revision=644

3 files changed, 230 insertions, 5 deletions

diff --git a/app-emulation/virtualbox-ose/ChangeLog b/app-emulation/virtualbox-ose/ChangeLog
index b371d7b..423ea7b 100644
--- a/app-emulation/virtualbox-ose/ChangeLog
+++ b/app-emulation/virtualbox-ose/ChangeLog
@@ -1,10 +1,31 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.10 2009/03/03 07:11:05 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.14 2009/03/22 13:36:43 patrick Exp $
 
-  04 Mar 2009; Alessio Cassibba (X-Drum) <swapon@gmail.com>
-  virtualbox-ose-2.1.4.ebuild:
-  Update SRC_URI due to upstream change
+  08 Apr 2009; Alessio Cassibba (X-Drum) <swapon@gmail.com>
+  +virtualbox-ose-2.2.0.ebuild:
+  Version bump; update DEPEND to use recent versions of kBuild and gsoap
+
+  22 Mar 2009; Patrick Lauer <patrick@gentoo.org>
+  virtualbox-ose-2.1.4-r2.ebuild:
+  Fixing dependencies: sdl needs to be built with USE=video. Fixes #263312
+
+*virtualbox-ose-2.1.4-r2 (21 Mar 2009)
+
+  21 Mar 2009; Patrick Lauer <patrick@gentoo.org>
+  +virtualbox-ose-2.1.4-r2.ebuild:
+  Undo last fix as upstream already did so. Fixes #262271
+
+  11 Mar 2009; Markus Ullmann <jokey@gentoo.org>
+  virtualbox-ose-2.1.4-r1.ebuild:
+  Apply Config.kmk fix wrt bug #251335
+
+*virtualbox-ose-2.1.4-r1 (05 Mar 2009)
+
+  05 Mar 2009; Mike Frysinger <vapier@gentoo.org>
+  -virtualbox-ose-2.1.4.ebuild, +virtualbox-ose-2.1.4-r1.ebuild:
+  Update to the latest 2.1.4 src tarball #260331 and cleanup the ebuild in
+  general.
 
 *virtualbox-ose-2.1.4 (03 Mar 2009)
 
diff --git a/app-emulation/virtualbox-ose/Manifest b/app-emulation/virtualbox-ose/Manifest
index 61873c2..f10d925 100644
--- a/app-emulation/virtualbox-ose/Manifest
+++ b/app-emulation/virtualbox-ose/Manifest
@@ -11,7 +11,9 @@ AUX virtualbox-ose-fix-nodbus-build.patch 461 RMD160 f9e731a1d68947823d23bdfd4bc
 AUX virtualbox-ose-interfaces 218 RMD160 4639b9848cf44ac59cd12585a3c56ef53d72a6d9 SHA1 3268e5759286bdff1c5242598266e6c2a5b17e5d SHA256 50ddbfedce3afd41aad45163eb799fce0956d815948ad9da842f09163aaafd52
 AUX virtualbox-ose.desktop 202 RMD160 8b4b5c05743978d71edd4eaba71ae25f1d9d0d82 SHA1 3c10d2f12ea58ef35e785b8727a51fd3a0d66472 SHA256 9bbd26661317b106593d74b84cec3781b24c41bc40a2f98776e23d6b422ee4bb
 DIST VirtualBox-1.6.6-OSE.tar.bz2 35483853 RMD160 4b17428371089806cf6f5e52d1905936f7beb01d SHA1 7c323b35d77277c650cbce2821ab6778d1e3270e SHA256 acb3c20ef751ed408489d7b5c2d5d441226055a6e83bfeb9258ce2d55baba4da
+DIST VirtualBox-2.2.0-OSE.tar.bz2 50432438 RMD160 0c74441fe812c8fd35ae460b847d255b8dadf0aa SHA1 016a159009cd626542302ea31fd500cadb049fb9 SHA256 8bf621cfcb61f2b0a71be53f072e58c3fb4f3183324faa3947346ff973314c71
 EBUILD virtualbox-ose-1.6.6-r1.ebuild 5993 RMD160 8c6d79e27f62919d45d2e2723e67eb450686969a SHA1 0cf299bee2c373762effd91457533737610b8b3a SHA256 7a30240d9a13b0b82c5c5fa531924c3118a7c4b871d7bf4c5f6b003562342492
+EBUILD virtualbox-ose-2.2.0.ebuild 6079 RMD160 cea20e8a988bd235c40734f211408c92fe6e3254 SHA1 d18eaec47d6f538908d3ea0aeefcd5f2a8c5e006 SHA256 3d070f8a17832989c8929bd5059f028952f691b563f71cfe7354af53a2a485ce
 EBUILD virtualbox-ose-9999.ebuild 5379 RMD160 e2f934a615723c668303dad1ed0e517e4513e599 SHA1 377f457cbaf0e414ebdd424abf02d7e665f7aa90 SHA256 677d809c891a2bfe51c66bf7e989e8501ebb1112d0989b6eba0f48a583b91532
-MISC ChangeLog 16263 RMD160 f189962ce89f68a0ba66265075bf4c9af0323b0a SHA1 bd926079eb055dfc259622f4182910323918827f SHA256 9829abfd685eb905b950ac1b78a32df30bb0f63997effb5ed768440170e216f3
+MISC ChangeLog 17006 RMD160 24fbd44b72ff4789c54b806e57de8c473fb1036c SHA1 0eb383bba8708a05ee724dcf27cd5fdfb23edaf7 SHA256 35b3dc7703940b26f334687019edd8114d2b5bd6f5b26d736a524e2e8365fce2
 MISC metadata.xml 608 RMD160 05b2e56d330d28aed13d4a7035369e04dc1e989e SHA1 ea332f57fa454cc6f8489f6debcd991003886fc0 SHA256 ab349ab6727625054f24bbf733a3f6fabb34ba1e1f0fd845c51c70595b05b6aa
diff --git a/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild b/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild
new file mode 100644
index 0000000..0c94dcd
--- /dev/null
+++ b/app-emulation/virtualbox-ose/virtualbox-ose-2.2.0.ebuild
@@ -0,0 +1,202 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-2.1.4-r2.ebuild,v 1.2 2009/03/22 13:36:43 patrick Exp $
+
+EAPI=2
+
+inherit eutils fdo-mime flag-o-matic linux-info pax-utils qt4 toolchain-funcs
+
+if [[ ${PV} == "9999" ]] ; then
+	# XXX: should finish merging the -9999 ebuild into this one ...
+	ESVN_REPO_URI="http://www.virtualbox.org/svn/vbox/trunk"
+	inherit linux-mod subversion
+else
+	MY_P=VirtualBox-${PV}-OSE
+	SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"
+	S=${WORKDIR}/${MY_P/-OSE/_OSE}
+fi
+
+DESCRIPTION="Software family of powerful x86 virtualization"
+HOMEPAGE="http://www.virtualbox.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+additions alsa +hal headless pulseaudio python +qt4 sdk vboxwebsrv"
+
+RDEPEND="!app-emulation/virtualbox-bin
+	~app-emulation/virtualbox-modules-${PV}
+	dev-libs/libIDL
+	>=dev-libs/libxslt-1.1.19
+	!headless? (
+		qt4? ( || ( ( x11-libs/qt-gui x11-libs/qt-core ) =x11-libs/qt-4.3*:4 ) )
+		x11-libs/libXcursor
+		media-libs/libsdl[X,video]
+		x11-libs/libXt
+	)"
+DEPEND="${RDEPEND}
+	>=dev-util/kbuild-0.1.5-r1
+	>=dev-lang/yasm-0.6.2
+	sys-devel/bin86
+	sys-devel/dev86
+	sys-power/iasl
+	media-libs/libpng
+	sys-libs/libcap
+	alsa? ( >=media-libs/alsa-lib-1.0.13 )
+	hal? ( sys-apps/hal )
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( >=dev-lang/python-2.3 )
+	vboxwebsrv? ( >=net-libs/gsoap-2.7.9f )"
+RDEPEND="${RDEPEND}
+	additions? ( ~app-emulation/virtualbox-ose-additions-${PV} )
+	sys-apps/usermode-utilities
+	net-misc/bridge-utils"
+
+pkg_setup() {
+	if ! use headless && ! use qt4 ; then
+		einfo "No USE=\"qt4\" selected, this build will not include"
+		einfo "any Qt frontend."
+	elif use headless && use qt4 ; then
+		einfo "You selected USE=\"headless qt4\", defaulting to"
+		einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
+	fi
+}
+
+src_prepare() {
+	# Remove shipped binaries (kBuild,yasm), see bug #232775
+	rm -rf kBuild/bin tools
+
+	# Disable things unused or split into separate ebuilds
+	sed -e "s/MY_LIBDIR/$(get_libdir)/" \
+		"${FILESDIR}"/${PN}-2-localconfig > LocalConfig.kmk || die
+}
+
+src_configure() {
+	local myconf
+	use alsa       || myconf="${myconf} --disable-alsa"
+	use pulseaudio || myconf="${myconf} --disable-pulse"
+	use python     || myconf="${myconf} --disable-python"
+	use hal        || myconf="${myconf} --disable-dbus"
+	use vboxwebsrv && myconf="${myconf} --enable-webservice"
+	if ! use headless ; then
+		use qt4 || myconf="${myconf} --disable-qt4"
+	else
+		myconf="${myconf} --build-headless"
+	fi
+	# not an autoconf script
+	./configure \
+		--with-gcc="$(tc-getCC)" \
+		--with-g++="$(tc-getCXX)" \
+		--disable-kmods \
+		${myconf} \
+		|| die "configure failed"
+}
+
+src_compile() {
+	source ./env.sh
+
+	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
+	# and strip all flags
+	strip-flags
+
+	MAKE="kmk" emake \
+		TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
+		TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
+		TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
+		TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
+		TOOL_YASM_AS=yasm KBUILD_PATH="${S}/kBuild" \
+		all || die "kmk failed"
+}
+
+src_install() {
+	cd "${S}"/out/linux.*/release/bin || die
+
+	# Create configuration files
+	insinto /etc/vbox
+	newins "${FILESDIR}/${PN}-2-config" vbox.cfg
+
+	# Set the right libdir
+	sed -i \
+		-e "s/MY_LIBDIR/$(get_libdir)/" \
+		"${D}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"
+
+	# Symlink binaries to the shipped wrapper
+	exeinto /usr/$(get_libdir)/${PN}
+	newexe "${FILESDIR}/${PN}-2-wrapper" "VBox" || die
+	fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBox
+	fperms 0750 /usr/$(get_libdir)/${PN}/VBox
+
+	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxManage
+	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxVRDP
+	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxHeadless
+	dosym /usr/$(get_libdir)/${PN}/VBoxTunctl /usr/bin/VBoxTunctl
+
+	# Install binaries and libraries
+	insinto /usr/$(get_libdir)/${PN}
+	doins -r components || die
+
+	if use sdk ; then
+		doins -r sdk || die
+	fi
+
+	if use vboxwebsrv ; then
+		doins vboxwebsrv || die
+		fowners root:vboxusers /usr/$(get_libdir)/${PN}/vboxwebsrv
+		fperms 0750 /usr/$(get_libdir)/${PN}/vboxwebsrv
+		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/vboxwebsrv
+		newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
+		newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
+	fi
+
+	for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl} *so *r0 *gc ; do
+		doins $each || die
+		fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
+		fperms 0750 /usr/$(get_libdir)/${PN}/${each}
+	done
+
+	if ! use headless ; then
+		for each in VBox{SDL,Headless} ; do
+			doins $each || die
+			fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
+			fperms 4750 /usr/$(get_libdir)/${PN}/${each}
+			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/${each}
+		done
+
+		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxSDL
+
+		if use qt4 ; then
+			doins VirtualBox || die
+			fowners root:vboxusers /usr/$(get_libdir)/${PN}/VirtualBox
+			fperms 4750 /usr/$(get_libdir)/${PN}/VirtualBox
+			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VirtualBox
+
+			dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VirtualBox
+		fi
+
+		newicon	"${S}"/src/VBox/Frontends/VirtualBox/images/OSE/VirtualBox_32px.png ${PN}.png
+		domenu "${FILESDIR}"/${PN}.desktop
+	else
+		doins VBoxHeadless || die
+		fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxHeadless
+		fperms 4750 /usr/$(get_libdir)/${PN}/VBoxHeadless
+		pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VBoxHeadless
+	fi
+
+	insinto /usr/share/${PN}
+	doins -r nls
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	if ! use headless ; then
+		elog "To launch VirtualBox just type: \"VirtualBox\""
+	fi
+	elog "You must be in the vboxusers group to use VirtualBox."
+	elog ""
+	elog "The lastest user manual is available for download at:"
+	elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}