gnome-extra/gnome-globalmenu: import ebuilds

6 files changed, 175 insertions, 0 deletions

diff --git a/gnome-extra/gnome-globalmenu/ChangeLog b/gnome-extra/gnome-globalmenu/ChangeLog
new file mode 100644
index 0000000..12d7978
--- /dev/null
+++ b/gnome-extra/gnome-globalmenu/ChangeLog
@@ -0,0 +1,13 @@
+# ChangeLog for gnome-extra/gnome-globalmenu
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header$
+
+*gnome-globalmenu-9999 (18 Apr 2010)
+*gnome-globalmenu-0.7.8 (18 Apr 2010)
+
+  18 Apr 2010; Gilles Dartiguelongue <eva@gentoo.org>
+  +files/gnome-globalmenu-0.7.7-as-needed.patch,
+  +gnome-globalmenu-0.7.8.ebuild, +gnome-globalmenu-9999.ebuild,
+  +metadata.xml:
+  Initial commit
+
diff --git a/gnome-extra/gnome-globalmenu/Manifest b/gnome-extra/gnome-globalmenu/Manifest
new file mode 100644
index 0000000..ffe4239
--- /dev/null
+++ b/gnome-extra/gnome-globalmenu/Manifest
@@ -0,0 +1,6 @@
+AUX gnome-globalmenu-0.7.7-as-needed.patch 502 RMD160 e358deb2b669b917bc21b3bda518141c2729d6bb SHA1 5b043c887a6f20f4d4cfb5632cb3060eaf17a994 SHA256 477fd29377204445b11304fe0c3ddab397850f06faf70d58c473d5a8de951663
+DIST gnome-globalmenu-0.7.8.tar.bz2 572224 RMD160 4690f4b744fb73a403462334c6126b63ad79cf45 SHA1 738c1ef87a7dca68d574efb2bcc52357909a9de4 SHA256 ad3f85c5a2f43ee13f9e03bbf276bd79a9bf685a7ba10484dd0dca54f00e4020
+EBUILD gnome-globalmenu-0.7.8.ebuild 1260 RMD160 f56aac0c35e3e48add0dcb32781f28c772858633 SHA1 41f17e76fd9e6770329266951b80d42d1f96447c SHA256 7e49b290508619981d4f898438ce64d1db81a27b2a370c9bf00132948f6ac868
+EBUILD gnome-globalmenu-9999.ebuild 1653 RMD160 3a4da0fc2268255078bc973899a5ef09c97054ea SHA1 65e875cea13a09ae09e2e94f34552d4fa1083515 SHA256 464bba816369df36d886f68237558ee07ce3f7187fed724cac5a099dae5d5499
+MISC ChangeLog 406 RMD160 4f48431a5b6893400f7507a28f384e00d5bdc99e SHA1 f62ac85d3b0a6498f241533ad6fad06190714523 SHA256 ef1f34dffbc9d0714f0ed61051c55bd11c911eab2697f0bb2afd20df2b28755d
+MISC metadata.xml 294 RMD160 48cf3784538ca27f89b2c2e03b34283197cba253 SHA1 113567b69a0b2caaf3632e5e5bed7656218dde8a SHA256 7ca1ffeb81230b4d6549e38a859ef2d1d1de560fbed967302effd11b977bf2c9
diff --git a/gnome-extra/gnome-globalmenu/files/gnome-globalmenu-0.7.7-as-needed.patch b/gnome-extra/gnome-globalmenu/files/gnome-globalmenu-0.7.7-as-needed.patch
new file mode 100644
index 0000000..b6c9db9
--- /dev/null
+++ b/gnome-extra/gnome-globalmenu/files/gnome-globalmenu-0.7.7-as-needed.patch
@@ -0,0 +1,14 @@
+--- a/libgnomenu/Makefile.am	2009-10-12 02:19:48.000000000 +0200
++++ b/libgnomenu/Makefile.am	2009-10-12 02:17:55.000000000 +0200
+@@ -36,7 +36,10 @@
+ 			 -include $(CONFIG_HEADER) \
+ 			 -include ../legacy-support/legacy-support.h
+ 
+-libgnomenu_la_LIBADD = ../legacy-support/liblegacy-support.la
++libgnomenu_la_LIBADD = ../legacy-support/liblegacy-support.la \
++			 $(GTK_LIBS) \
++			 $(WNCK_LIBS) \
++			 $(X11_LIBS)
+ 
+ libgnomenu_la_LDFLAGS = -version-info 2:0:0 -release $(VERSION) -Wl,--as-needed
+ 
diff --git a/gnome-extra/gnome-globalmenu/gnome-globalmenu-0.7.8.ebuild b/gnome-extra/gnome-globalmenu/gnome-globalmenu-0.7.8.ebuild
new file mode 100644
index 0000000..c83aceb
--- /dev/null
+++ b/gnome-extra/gnome-globalmenu/gnome-globalmenu-0.7.8.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit autotools eutils gnome2
+
+MY_P=${P/_p/_}
+
+DESCRIPTION="Global menubar applet for Gnome2."
+HOMEPAGE="http://code.google.com/p/gnome2-globalmenu/"
+SRC_URI="http://gnome2-globalmenu.googlecode.com/files/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gnome test xfce"
+
+RDEPEND=">=x11-libs/gtk+-2.10.0
+	>=dev-libs/glib-2.10.0
+	>=gnome-base/gconf-2
+	>=x11-libs/libwnck-2.16.0
+	>=gnome-base/gnome-menus-2.16.0
+	gnome? (
+		>=gnome-base/gnome-panel-2.16.0
+		>=x11-libs/libnotify-0.4.4 )
+	xfce? (
+		>=xfce-base/xfce4-panel-4.4.3 )
+	>=x11-libs/libX11-1.1.0"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	>=dev-lang/vala-0.7.7"
+
+S="${WORKDIR}/${MY_P}"
+DOCS="AUTHORS ChangeLog NEWS README*"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--without-gir
+		--docdir=/usr/share/doc/${PF}
+		$(use_enable test tests)
+		$(use_with gnome gnome-panel)
+		$(use_with xfce xfce4-panel)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Fix compilation problem with --as-needed
+	epatch "${FILESDIR}/${PN}-0.7.7-as-needed.patch"
+
+	intltoolize --force --copy --automake || die "intltoolize failed"
+	AT_M4DIR="autotools" eautoreconf
+}
diff --git a/gnome-extra/gnome-globalmenu/gnome-globalmenu-9999.ebuild b/gnome-extra/gnome-globalmenu/gnome-globalmenu-9999.ebuild
new file mode 100644
index 0000000..7ebcfe1
--- /dev/null
+++ b/gnome-extra/gnome-globalmenu/gnome-globalmenu-9999.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit autotools eutils gnome2
+
+if [[ ${PV} == "9999" ]]; then
+	ESVN_REPO_URI="http://gnome2-globalmenu.googlecode.com/svn/trunk/"
+	SRC_URI=""
+	inherit subversion
+else
+	MY_P=${P/_p/_}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="http://gnome2-globalmenu.googlecode.com/files/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Global menubar applet for Gnome2."
+HOMEPAGE="http://code.google.com/p/gnome2-globalmenu/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gnome test xfce"
+
+# XXX: vala dependency raised for build issues
+RDEPEND=">=x11-libs/gtk+-2.10.0
+	>=dev-libs/glib-2.10.0
+	>=gnome-base/gconf-2
+	>=x11-libs/libwnck-2.16.0
+	>=gnome-base/gnome-menus-2.16.0
+	gnome? (
+		>=gnome-base/gnome-panel-2.16.0
+		>=x11-libs/libnotify-0.4.4 )
+	xfce? (
+		>=xfce-base/xfce4-panel-4.4.3 )
+	>=x11-libs/libX11-1.1.0"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	>=dev-lang/vala-0.7.7"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--without-gir
+		--docdir=/usr/share/doc/${PF}
+		$(use_enable test tests)
+		$(use_with gnome gnome-panel)
+		$(use_with xfce xfce4-panel)"
+}
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]]; then
+		subversion_src_unpack
+	else
+		unpack ${A}
+	fi
+	cd "${S}"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# INSTALL is not useful or existing depending on version
+	sed 's/\(doc_DATA.*\)INSTALL/\1/' \
+		-i Makefile.am || die "sed failed"
+
+	# Fix compilation problem with --as-needed
+	epatch "${FILESDIR}/${PN}-0.7.7-as-needed.patch"
+
+	intltoolize --force --copy --automake || die "intltoolize failed"
+	AT_M4DIR="autotools" eautoreconf
+}
diff --git a/gnome-extra/gnome-globalmenu/metadata.xml b/gnome-extra/gnome-globalmenu/metadata.xml
new file mode 100644
index 0000000..423f72a
--- /dev/null
+++ b/gnome-extra/gnome-globalmenu/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>no-herd</herd>
+<maintainer>
+	<email>eva@gentoo.org</email>
+	<name>Gilles Dartiguelongue</name>
+</maintainer>
+<use>
+	<flag name="xfce"></flag>
+</use>
+</pkgmetadata>