dev-python/simpy/simpy-2.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/simpy/simpy-2.3.ebuild,v 1.2 2012/01/07 00:17:17 mr_bones_ Exp $

EAPI=4

PYTHON_DEPEND="2:2.6"
PYTHON_USE_WITH="tk"
SUPPORT_PYTHON_ABIS="1"
# https://sourceforge.net/tracker/?func=detail&aid=3470332&group_id=62366&atid=500345
RESTRICT_PYTHON_ABIS="3.*"
PYTHON_MODNAME="SimPy"

inherit distutils

MY_P="${P/simpy/SimPy}"

DESCRIPTION="Simulation in Python is an object-oriented, process-based discrete-event simulation language"
HOMEPAGE="http://simpy.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
LICENSE="LGPL-2.1"
IUSE="doc test"

RDEPEND=""
DEPEND="test? ( dev-python/pytest )"

S="${WORKDIR}/${MY_P}"

src_test() {
	testing() {
		PYTHONPATH="." $(PYTHON) -c "import SimPy; SimPy.test()" || die
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r SimPyDocs
		dodoc SimPyModels/*
	fi
}