app-shells/autojump/autojump-21.3.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-shells/autojump/autojump-21.3.0-r1.ebuild,v 1.3 2013/09/05 19:44:43 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )

inherit eutils python-r1 python-utils-r1 vcs-snapshot

DESCRIPTION="change directory command that learns"
HOMEPAGE="http://github.com/joelthelion/autojump"
SRC_URI="https://github.com/joelthelion/${PN}/archive/release-v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bash-completion python test zsh-completion"

RDEPEND="bash-completion? ( >=app-shells/bash-4 )
	python? ( ${PYTHON_DEPS} )
	zsh-completion? ( app-shells/zsh app-shells/zsh-completion )"
DEPEND="test? ( ${PYTHON_DEPS} )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-supported-shells.patch
}

src_compile() {
	true
}

src_install() {
	dobin bin/autojump

	insinto /etc/profile.d
	doins bin/${PN}.sh

	if use bash-completion ; then
		doins bin/${PN}.bash
	fi

	if use zsh-completion ; then
		doins bin/${PN}.zsh
		insinto /usr/share/zsh/site-functions
		doins bin/_j
	fi

	if use python ; then
		python_foreach_impl python_domodule tools/autojump_ipython.py

		einfo "This tool provides \"j\" for ipython, please add"
		einfo "\"import autojump_ipython\" to your ipy_user_conf.py."
	fi

	doman docs/${PN}.1
	dodoc README.md

	elog "loading of insecure relative path \"custom_install\" has been"
	elog "remove. See ${EPREFIX}/etc/profile.d/${PN}.sh for details."
}