blob: 009e966985c218c66c94ca01e497beef2e893724 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-dicts/wordnet/wordnet-3.0-r4.ebuild,v 1.4 2015/03/25 13:58:35 ago Exp $
EAPI=5
inherit autotools eutils flag-o-matic multilib
DESCRIPTION="A lexical database for the English language"
HOMEPAGE="http://wordnet.princeton.edu/"
SRC_URI="
ftp://ftp.cogsci.princeton.edu/pub/wordnet/${PV}/WordNet-${PV}.tar.gz
mirror://gentoo/${P}-patchset-1.tar.bz2"
LICENSE="Princeton"
SLOT="0"
KEYWORDS="amd64 ~ppc x86 ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
IUSE="doc"
# In contrast to what the configure script seems to imply, Tcl/Tk is NOT optional.
# cf. bug 163478 for details. (Yes, it's about 2.1 but it's still the same here.)
DEPEND="
dev-lang/tcl:0=
dev-lang/tk:0="
RDEPEND="${DEPEND}"
S="${WORKDIR}/WordNet-${PV}"
PATCHES=(
# Don't install into PREFIX/dict but PREFIX/share/wordnet/dict
"${WORKDIR}/${P}-dict-location.patch"
# Fixes bug 130024, make an additional shared lib
"${WORKDIR}/${P}-shared-lib.patch"
# Don't install the docs directly into PREFIX/doc but PREFIX/doc/PN
"${WORKDIR}/${P}-docs-path.patch"
"${WORKDIR}"/${P}-CVE-2008-3908.patch #211491
"${WORKDIR}"/${P}-CVE-2008-2149.patch #211491
"${FILESDIR}"/${P}-tcl8.6.patch
"${FILESDIR}"/${P}-format-security.patch
"${FILESDIR}"/${P}-src_stubs_c.patch
)
src_prepare() {
epatch ${PATCHES[@]}
# Don't install all the extra docs (html, pdf, ps) without doc USE flag.
if ! use doc; then
sed -i -e "s:SUBDIRS =.*:SUBDIRS = man:" doc/Makefile.am || die
fi
# Drop installation of OLD tk.h headers #255590
sed '/^SUBDIRS/d' -i include/Makefile.am || die
sed 's: include/tk/Makefile::' -i configure.ac || die
rm -rf include/tk/ || die
rm -f configure || die
eautoreconf
MAKEOPTS+=" -e"
}
src_configure() {
append-cppflags -DUNIX -I"${T}"/usr/include
PLATFORM=linux WN_ROOT="${T}/usr" \
WN_DICTDIR="${T}/usr/share/wordnet/dict" \
WN_MANDIR="${T}/usr/share/man" \
WN_DOCDIR="${T}/usr/share/doc/wordnet-${PV}" \
WNHOME="${EPREFIX}/usr/share/wordnet" \
econf \
--with-tcl="${EPREFIX}"/usr/$(get_libdir) \
--with-tk="${EPREFIX}"/usr/$(get_libdir)
}
|
GitWeb
