1 files changed, 51 insertions, 0 deletions
diff --git a/media-libs/libvisual/libvisual-0.4.0-r3.ebuild b/media-libs/libvisual/libvisual-0.4.0-r3.ebuild
new file mode 100644
index 000000000000..051e0fbd4ac9
--- /dev/null
+++ b/media-libs/libvisual/libvisual-0.4.0-r3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libvisual/libvisual-0.4.0-r3.ebuild,v 1.1 2013/08/10 20:36:40 aballier Exp $
+
+EAPI=5
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+
+inherit autotools-multilib
+
+DESCRIPTION="Libvisual is an abstraction library that comes between applications and audio visualisation plugins."
+HOMEPAGE="http://libvisual.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0.4"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="debug nls static-libs threads"
+
+RDEPEND="abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r9
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-better-altivec-detection.patch
+	"${FILESDIR}"/${P}-inlinedefineconflict.patch
+	)
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/libvisual-0.4/libvisual/lvconfig.h
+)
+
+src_prepare() {
+	autotools-multilib_src_prepare
+	# autogenerated, causes problems for out of tree builds
+	rm -f libvisual/lvconfig.h || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_enable nls)
+		$(use_enable threads)
+		$(use_enable debug)
+	)
+	autotools-multilib_src_configure
+}