Don't hardcode /usr/local/lib in import-fdi-quirkdb script wrt #319139 by Peter Gantner.

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 69 insertions, 1 deletions

diff --git a/sys-power/pm-utils/ChangeLog b/sys-power/pm-utils/ChangeLog
index 78bfc15609d1..1e4476c8d67b 100644
--- a/sys-power/pm-utils/ChangeLog
+++ b/sys-power/pm-utils/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-power/pm-utils
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/pm-utils/ChangeLog,v 1.39 2010/05/10 18:04:40 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/pm-utils/ChangeLog,v 1.40 2010/05/14 19:37:25 ssuominen Exp $
+
+*pm-utils-1.3.0-r3 (14 May 2010)
+
+  14 May 2010; Samuli Suominen <ssuominen@gentoo.org>
+  +pm-utils-1.3.0-r3.ebuild:
+  Don't hardcode /usr/local/lib in import-fdi-quirkdb script wrt #319139 by
+  Peter Gantner.
 
   10 May 2010; nixnut <nixnut@gentoo.org> pm-utils-1.3.0-r2.ebuild:
   ppc stable #318209
diff --git a/sys-power/pm-utils/pm-utils-1.3.0-r3.ebuild b/sys-power/pm-utils/pm-utils-1.3.0-r3.ebuild
new file mode 100644
index 000000000000..c58ab1b07e8a
--- /dev/null
+++ b/sys-power/pm-utils/pm-utils-1.3.0-r3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/pm-utils/pm-utils-1.3.0-r3.ebuild,v 1.1 2010/05/14 19:37:25 ssuominen Exp $
+
+EAPI=2
+inherit autotools eutils multilib
+
+DESCRIPTION="Suspend and hibernation utilities"
+HOMEPAGE="http://pm-utils.freedesktop.org/"
+SRC_URI="http://pm-utils.freedesktop.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="alsa debug networkmanager ntp video_cards_intel video_cards_radeon"
+
+vbetool="!video_cards_intel? ( sys-apps/vbetool )"
+RDEPEND="
+	!sys-power/powermgmt-base
+	sys-apps/dbus
+	>=sys-apps/util-linux-2.13
+	sys-power/pm-quirks
+	alsa? ( media-sound/alsa-utils )
+	networkmanager? ( net-misc/networkmanager )
+	ntp? ( net-misc/ntp )
+	amd64? ( ${vbetool} )
+	x86? ( ${vbetool} )
+	video_cards_radeon? ( app-laptop/radeontool )"
+DEPEND="app-text/xmlto
+	app-text/docbook-xml-dtd:4.5"
+
+src_prepare() {
+	local ignore="01grub"
+	use networkmanager || ignore+=" 55NetworkManager"
+	use ntp || ignore+=" 90clock"
+
+	use debug && echo 'PM_DEBUG="true"' > "${S}/gentoo"
+	echo "HOOK_BLACKLIST=\"${ignore}\"" >> "${S}/gentoo"
+
+	epatch "${FILESDIR}"/${PV}-fix_autotools.patch \
+		"${FILESDIR}"/${PV}-on_ac_power-upower.patch
+
+	sed -i \
+		-e "s:/usr/local/lib:/usr/$(get_libdir):" \
+		src/import-fdi-quirkdb || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS pm/HOWTO* README* TODO || die
+
+	insinto /etc/pm/config.d
+	doins gentoo || die
+}