Version bump (bug #292594). Fix permissions (bug #294716). Set SUPPORT_PYTHON_ABIS.

(Portage version: 14899-svn/cvs/Linux x86_64)

3 files changed, 121 insertions, 70 deletions

diff --git a/sys-fs/ecryptfs-utils/ChangeLog b/sys-fs/ecryptfs-utils/ChangeLog
index 67343057dcdc..05b9f2f5b9a6 100644
--- a/sys-fs/ecryptfs-utils/ChangeLog
+++ b/sys-fs/ecryptfs-utils/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-fs/ecryptfs-utils
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog,v 1.27 2009/09/17 13:58:51 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog,v 1.28 2009/11/27 19:44:24 arfrever Exp $
+
+*ecryptfs-utils-82 (27 Nov 2009)
+
+  27 Nov 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  -ecryptfs-utils-76.ebuild, +ecryptfs-utils-82.ebuild:
+  Version bump (bug #292594). Fix permissions (bug #294716). Set
+  SUPPORT_PYTHON_ABIS.
 
   17 Sep 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   ecryptfs-utils-79.ebuild:
diff --git a/sys-fs/ecryptfs-utils/ecryptfs-utils-76.ebuild b/sys-fs/ecryptfs-utils/ecryptfs-utils-76.ebuild
deleted file mode 100644
index 0e460479f168..000000000000
--- a/sys-fs/ecryptfs-utils/ecryptfs-utils-76.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2009 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-76.ebuild,v 1.1 2009/07/18 00:27:21 arfrever Exp $
-
-EAPI="2"
-
-inherit autotools pam
-
-DESCRIPTION="eCryptfs userspace utilities"
-HOMEPAGE="http://launchpad.net/ecryptfs"
-SRC_URI="http://launchpad.net/ecryptfs/trunk/${PV}/+download/${PN}_${PV}.orig.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc gpg gtk nss openssl pam pkcs11 python suid tpm"
-
-RDEPEND=">=sys-apps/keyutils-1.0
-	>=dev-libs/libgcrypt-1.2.0
-	gpg? ( app-crypt/gpgme )
-	gtk? ( x11-libs/gtk+ )
-	nss? ( dev-libs/nss )
-	openssl? ( >=dev-libs/openssl-0.9.7 )
-	pam? ( sys-libs/pam )
-	pkcs11? (
-		>=dev-libs/openssl-0.9.7
-		>=dev-libs/pkcs11-helper-1.04
-	)
-	python? ( >=dev-lang/python-2.5 )
-	tpm? ( app-crypt/trousers )"
-DEPEND="${RDEPEND}
-	>=dev-util/pkgconfig-0.9.0
-	python? ( dev-lang/swig )"
-
-S="${WORKDIR}/${PN}_${PV}.orig"
-
-src_prepare() {
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		--docdir="/usr/share/doc/${PF}" \
-		--with-pamdir=$(getpam_mod_dir) \
-		$(use_enable doc docs) \
-		$(use_enable gpg) \
-		$(use_enable gtk gui) \
-		$(use_enable nss) \
-		$(use_enable openssl) \
-		$(use_enable pam) \
-		$(use_enable pkcs11 pkcs11-helper) \
-		$(use_enable python pywrap) \
-		$(use_enable tpm tspi)
-}
-
-src_install(){
-	emake DESTDIR="${D}" install || die "emake install failed"
-	use suid && fperms u+s /sbin/mount.ecryptfs
-}
-
-pkg_postinst() {
-	if use suid; then
-		ewarn
-		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
-		ewarn "means that if there are any undetected vulnerabilities in the binary,"
-		ewarn "then local users may be able to gain root access on your machine."
-		ewarn
-	fi
-}
diff --git a/sys-fs/ecryptfs-utils/ecryptfs-utils-82.ebuild b/sys-fs/ecryptfs-utils/ecryptfs-utils-82.ebuild
new file mode 100644
index 000000000000..a6be32121fb1
--- /dev/null
+++ b/sys-fs/ecryptfs-utils/ecryptfs-utils-82.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-82.ebuild,v 1.1 2009/11/27 19:44:24 arfrever Exp $
+
+EAPI="2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit flag-o-matic pam python
+
+DESCRIPTION="eCryptfs userspace utilities"
+HOMEPAGE="http://launchpad.net/ecryptfs"
+SRC_URI="http://launchpad.net/ecryptfs/trunk/${PV}/+download/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc gpg gtk openssl pam pkcs11 python suid tpm"
+
+RDEPEND=">=sys-apps/keyutils-1.0
+	>=dev-libs/libgcrypt-1.2.0
+	dev-libs/nss
+	gpg? ( app-crypt/gpgme )
+	gtk? ( x11-libs/gtk+ )
+	openssl? ( >=dev-libs/openssl-0.9.7 )
+	pam? ( sys-libs/pam )
+	pkcs11? (
+		>=dev-libs/openssl-0.9.7
+		>=dev-libs/pkcs11-helper-1.04
+	)
+	python? ( >=dev-lang/python-2.5 )
+	tpm? ( app-crypt/trousers )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9.0
+	python? ( dev-lang/swig )"
+RESTRICT_PYTHON_ABIS="2.4 3.*"
+
+pkg_setup() {
+	append-flags -D_FILE_OFFSET_BITS=64
+}
+
+src_prepare() {
+	# Python bindings are built/installed manually.
+	sed -e "/SUBDIRS =/s/ libecryptfs-swig//" -i src/Makefile.{am,in} || die "sed failed"
+}
+
+src_configure() {
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--enable-nss \
+		--with-pamdir=$(getpam_mod_dir) \
+		$(use_enable doc docs) \
+		$(use_enable gpg) \
+		$(use_enable gtk gui) \
+		$(use_enable openssl) \
+		$(use_enable pam) \
+		$(use_enable pkcs11 pkcs11-helper) \
+		$(use_enable python pywrap) \
+		$(use_enable tpm tspi)
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		python_copy_sources src/libecryptfs-swig
+		building() {
+			emake \
+				PYTHON="$(PYTHON)" \
+				PYTHON_CPPFLAGS="-I$(python_get_includedir)" \
+				PYTHON_LDFLAGS="-L$(python_get_libdir) -lpython${PYTHON_ABI}" \
+				PYTHON_SITE_PKG="$(python_get_sitedir)" \
+				PYTHON_VERSION="${PYTHON_ABI}" \
+				SWIG_PYTHON_CPPFLAGS="-I$(python_get_includedir)" \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)"
+		}
+		python_execute_function -s --source-dir src/libecryptfs-swig building
+	fi
+}
+
+src_install(){
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	if use python; then
+		installation() {
+			emake \
+				DESTDIR="${D}" \
+				PYTHON="$(PYTHON)" \
+				PYTHON_CPPFLAGS="-I$(python_get_includedir)" \
+				PYTHON_LDFLAGS="-L$(python_get_libdir) -lpython${PYTHON_ABI}" \
+				PYTHON_SITE_PKG="$(python_get_sitedir)" \
+				PYTHON_VERSION="${PYTHON_ABI}" \
+				SWIG_PYTHON_CPPFLAGS="-I$(python_get_includedir)" \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)" \
+				install || return 1
+			echo "ecryptfs-utils" > "${D}$(python_get_sitedir)/ecryptfs-utils.pth"
+		}
+		python_execute_function -s --source-dir src/libecryptfs-swig installation
+	fi
+
+	use suid && fperms u+s /sbin/mount.ecryptfs_private
+}
+
+pkg_postinst() {
+	if use suid; then
+		ewarn
+		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
+		ewarn "means that if there are any undetected vulnerabilities in the binary,"
+		ewarn "then local users may be able to gain root access on your machine."
+		ewarn
+	fi
+}