Version bump.

(Portage version: 2.2.0_alpha29/cvs/Linux x86_64)

1 files changed, 89 insertions, 0 deletions

diff --git a/sys-devel/gcc/gcc-4.6.0.ebuild b/sys-devel/gcc/gcc-4.6.0.ebuild
new file mode 100644
index 000000000000..2ed5f139463e
--- /dev/null
+++ b/sys-devel/gcc/gcc-4.6.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/gcc-4.6.0.ebuild,v 1.1 2011/04/03 01:41:56 dirtyepic Exp $
+
+PATCH_VER="1.0"
+UCLIBC_VER="1.0"
+
+ETYPE="gcc-compiler"
+
+# Hardened gcc 4 stuff
+PIE_VER="0.4.5"
+SPECS_VER="0.2.0"
+SPECS_GCC_VER="4.4.3"
+# arch/libc configurations known to be stable with {PIE,SSP}-by-default
+PIE_GLIBC_STABLE="x86 amd64 ppc ppc64 arm ia64"
+PIE_UCLIBC_STABLE="x86 arm amd64 ppc ppc64"
+SSP_STABLE="amd64 x86 ppc ppc64 arm"
+# uclibc need tls and nptl support for SSP support
+SSP_UCLIBC_STABLE=""
+#end Hardened stuff
+
+inherit toolchain
+
+DESCRIPTION="The GNU Compiler Collection"
+
+LICENSE="GPL-3 LGPL-3 || ( GPL-3 libgcc libstdc++ gcc-runtime-library-exception-3.1 ) FDL-1.2"
+KEYWORDS=""
+IUSE=""
+
+RDEPEND=">=sys-libs/zlib-1.1.4
+	virtual/libiconv
+	>=dev-libs/gmp-4.3.2
+	>=dev-libs/mpfr-2.4.2
+	>=dev-libs/mpc-0.8.1
+	graphite? (
+		>=dev-libs/cloog-ppl-0.15.10
+		>=dev-libs/ppl-0.11
+	)
+	!build? (
+		gcj? (
+			gtk? (
+				x11-libs/libXt
+				x11-libs/libX11
+				x11-libs/libXtst
+				x11-proto/xproto
+				x11-proto/xextproto
+				=x11-libs/gtk+-2*
+				x11-libs/pango
+			)
+			>=media-libs/libart_lgpl-2.1
+			app-arch/zip
+			app-arch/unzip
+		)
+		nls? ( sys-devel/gettext )
+	)"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-util/dejagnu-1.4.4
+		>=sys-devel/autogen-5.5.4
+	)
+	>=sys-apps/texinfo-4.8
+	>=sys-devel/bison-1.875
+	>=sys-devel/flex-2.5.4
+	amd64? ( multilib? ( gcj? ( app-emulation/emul-linux-x86-xlibs ) ) )
+	>=${CATEGORY}/binutils-2.18"
+PDEPEND=">=sys-devel/gcc-config-1.4
+	go? ( >=sys-devel/gcc-config-1.5 )"
+
+if [[ ${CATEGORY} != cross-* ]] ; then
+	PDEPEND="${PDEPEND} elibc_glibc? ( >=sys-libs/glibc-2.8 )"
+fi
+
+src_unpack() {
+	toolchain_src_unpack
+
+	use vanilla && return 0
+
+	[[ ${CHOST} == ${CTARGET} ]] && epatch "${FILESDIR}"/gcc-spec-env.patch
+	[[ ${CTARGET} == *-softfloat-* ]] && epatch "${FILESDIR}"/4.4.0/gcc-4.4.0-softfloat.patch
+}
+
+pkg_setup() {
+	toolchain_pkg_setup
+
+	ewarn
+	ewarn "LTO support is still experimental and unstable."
+	ewarn "Any bugs resulting from the use of LTO will not be fixed."
+	ewarn
+}