Convert shebangs to make sure python2.7 is used and set dependency to python-2.7 since it does not work with python-2.6 (bug #421631).

(Portage version: 2.1.10.65/cvs/Linux x86_64)

3 files changed, 109 insertions, 3 deletions

diff --git a/net-wireless/blueman/ChangeLog b/net-wireless/blueman/ChangeLog
index aef1ae0e7b31..cf9d38b4a10f 100644
--- a/net-wireless/blueman/ChangeLog
+++ b/net-wireless/blueman/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-wireless/blueman
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.14 2012/06/19 06:10:22 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.15 2012/06/20 06:12:44 dev-zero Exp $
+
+*blueman-1.23-r2 (20 Jun 2012)
+
+  20 Jun 2012; Tiziano Müller <dev-zero@gentoo.org> +blueman-1.23-r2.ebuild,
+  blueman-1.23-r1.ebuild:
+  Convert shebangs to make sure python2.7 is used and set dependency to
+  python-2.7 since it does not work with python-2.6 (bug #421631).
 
 *blueman-1.23-r1 (19 Jun 2012)
 
diff --git a/net-wireless/blueman/blueman-1.23-r1.ebuild b/net-wireless/blueman/blueman-1.23-r1.ebuild
index 2a869272a475..80843743470d 100644
--- a/net-wireless/blueman/blueman-1.23-r1.ebuild
+++ b/net-wireless/blueman/blueman-1.23-r1.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.23-r1.ebuild,v 1.1 2012/06/19 06:10:22 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.23-r1.ebuild,v 1.2 2012/06/20 06:12:44 dev-zero Exp $
 
 EAPI="4"
 
-PYTHON_DEPEND="2"
+PYTHON_DEPEND="2:2.7"
 
 inherit eutils python gnome2-utils
 
diff --git a/net-wireless/blueman/blueman-1.23-r2.ebuild b/net-wireless/blueman/blueman-1.23-r2.ebuild
new file mode 100644
index 000000000000..1064e585cabd
--- /dev/null
+++ b/net-wireless/blueman/blueman-1.23-r2.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.23-r2.ebuild,v 1.1 2012/06/20 06:12:44 dev-zero Exp $
+
+EAPI="4"
+
+PYTHON_DEPEND="2:2.7"
+
+inherit eutils python gnome2-utils
+
+DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks."
+HOMEPAGE="http://blueman-project.org/"
+SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gconf sendto network nls policykit pulseaudio"
+
+CDEPEND="dev-libs/glib:2
+	>=x11-libs/gtk+-2.12:2
+	x11-libs/startup-notification
+	dev-python/pygobject:2
+	>=net-wireless/bluez-4.21"
+DEPEND="${CDEPEND}
+	nls? ( dev-util/intltool sys-devel/gettext )
+	virtual/pkgconfig
+	>=dev-python/pyrex-0.9.8"
+RDEPEND="${CDEPEND}
+	>=app-mobilephone/obex-data-server-0.4.4
+	sys-apps/dbus
+	dev-python/pygtk
+	dev-python/notify-python
+	dev-python/dbus-python
+	x11-themes/hicolor-icon-theme
+	gconf? ( dev-python/gconf-python )
+	sendto? ( gnome-base/nautilus )
+	network? ( || ( net-dns/dnsmasq
+		=net-misc/dhcp-3*
+		>=net-misc/networkmanager-0.8 ) )
+	policykit? ( sys-auth/polkit )
+	pulseaudio? ( media-sound/pulseaudio )"
+
+pkg_setup() {
+	python_set_active_version 2.7
+	python_pkg_setup
+}
+
+src_prepare() {
+	# disable pyc compiling
+	ln -sf $(type -P true) py-compile
+
+	sed -i \
+		-e '/^Encoding/d' \
+		data/blueman-manager.desktop.in || die "sed failed"
+
+	epatch \
+		"${FILESDIR}/${P}-plugins-conf-file.patch" \
+		"${FILESDIR}/${P}-fix-broken-status-icon.patch" \
+		"${FILESDIR}/${P}-set-codeset-for-gettext-to-UTF-8-always.patch"
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable policykit polkit) \
+		$(use_enable sendto) \
+		--disable-hal \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+
+	python_convert_shebangs 2.7 "${D}"/usr/bin/blueman-* "${D}/usr/libexec/blueman-mechanism"
+
+	rm "${D}"/$(python_get_sitedir)/*.la
+	use sendto && rm "${D}"/usr/lib*/nautilus-sendto/plugins/*.la
+
+	use gconf || rm "${D}"/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py
+	use policykit || rm -rf "${D}"/usr/share/polkit-1
+	use pulseaudio || rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py,plugins/applet/Pulse*.py}
+
+	python_need_rebuild
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	python_mod_optimize ${PN}
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${PN}
+	gnome2_icon_cache_update
+}