Version bump. New gnome use flag for gksu. New ewarn message

(Portage version: 2.2_rc67/cvs/Linux x86_64)

3 files changed, 71 insertions, 1 deletions

diff --git a/net-misc/dnetstats/ChangeLog b/net-misc/dnetstats/ChangeLog
index 6c4aaf0e1d51..d412b397654e 100644
--- a/net-misc/dnetstats/ChangeLog
+++ b/net-misc/dnetstats/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/dnetstats
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/dnetstats/ChangeLog,v 1.2 2010/03/09 12:19:40 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dnetstats/ChangeLog,v 1.3 2010/06/29 12:00:13 hwoarang Exp $
+
+*dnetstats-1.2.6 (29 Jun 2010)
+
+  29 Jun 2010; Markos Chandras <hwoarang@gentoo.org>
+  +dnetstats-1.2.6.ebuild, metadata.xml:
+  Version bump. Refactor sudo logic. Introduced a new gnome use flag which
+  pulls gksu for gnome users. Added extended ewarn message to warn uses
+  about the expected behavior
 
   09 Mar 2010; Jonathan Callen <abcd@gentoo.org> dnetstats-1.2.5.ebuild:
   QA: When not using an absolute path, you MUST NOT use a file extension
diff --git a/net-misc/dnetstats/dnetstats-1.2.6.ebuild b/net-misc/dnetstats/dnetstats-1.2.6.ebuild
new file mode 100644
index 000000000000..4c71ed0c68af
--- /dev/null
+++ b/net-misc/dnetstats/dnetstats-1.2.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dnetstats/dnetstats-1.2.6.ebuild,v 1.1 2010/06/29 12:00:13 hwoarang Exp $
+
+EAPI="2"
+
+inherit qt4-r2
+
+MY_PN="DNetStats"
+MY_P="${MY_PN}-v${PV}-release"
+
+DESCRIPTION="Qt4 network monitor utility"
+HOMEPAGE="http://qt-apps.org/content/show.php/DNetStats?content=107467"
+SRC_URI="http://qt-apps.org/CONTENT/content-files/107467-${MY_P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="kde gnome"
+
+DEPEND="x11-libs/qt-gui:4"
+RDEPEND="${DEPEND}
+	app-admin/sudo
+	kde? ( kde-base/kdesu )
+	gnome? ( x11-libs/gksu )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if ! use kde && ! use gnome; then
+		ewarn
+		ewarn "You didn't enable nor kde neither gnome use flags."
+		ewarn "This means that no sudo GUI frontend will be used hence"
+		ewarn "the ${PN} menu entry won't work for normal users."
+		ewarn "Use 'sudo ${PN}' to launch the application or emerge ${PN} with"
+		ewarn "USE='kde' or USE='gnome' in order to make use of a graphical"
+		ewarn "sudo frontend"
+		ewarn
+	fi
+}
+
+src_prepare() {
+	# remove old moc_* files
+	rm -rf moc_* || die "failed to remove old moc_* files"
+}
+
+src_install() {
+	local gsudo
+	newbin mythread ${PN} || die "newbin failed"
+	dodoc ReadMe || die "dodoc failed"
+	newicon resource/energy.png ${PN}.png || die "doicon failed"
+	make_desktop_entry ${PN} DNetStats ${PN} 'Qt;Network;Dialup'
+	# adjust the .desktop file
+	use kde && gsudo="kdesu"
+	use gnome && gsudo="gksu"
+	if [[ -n ${gsudo} ]]; then
+		sed -i "/^Exec/s:${PN}:${gsudo} -c ${PN}:" \
+			${D}/usr/share/applications/"${PN}"-"${PN}".desktop \
+			|| die "failed to fix desktop file"
+	fi
+}
diff --git a/net-misc/dnetstats/metadata.xml b/net-misc/dnetstats/metadata.xml
index 7e70f1538383..357b1150ad5e 100644
--- a/net-misc/dnetstats/metadata.xml
+++ b/net-misc/dnetstats/metadata.xml
@@ -8,6 +8,7 @@
 </maintainer>
 <use>
 <flag name="kde">Use kdesu to gain root access</flag>
+<flag name="gnome">Use gksu to gain root access</flag>
 </use>
 <longdescription lang="en">
 </longdescription>