Version bump.

(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

2 files changed, 96 insertions, 1 deletions

diff --git a/net-misc/ps3mediaserver/ChangeLog b/net-misc/ps3mediaserver/ChangeLog
index 50310316500b..b8f42689733a 100644
--- a/net-misc/ps3mediaserver/ChangeLog
+++ b/net-misc/ps3mediaserver/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/ps3mediaserver
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v 1.13 2012/07/01 00:38:05 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v 1.14 2012/08/05 03:29:50 floppym Exp $
+
+*ps3mediaserver-1.60.0 (05 Aug 2012)
+
+  05 Aug 2012; Mike Gilbert <floppym@gentoo.org> +ps3mediaserver-1.60.0.ebuild:
+  Version bump.
 
 *ps3mediaserver-1.54.0 (01 Jul 2012)
 
diff --git a/net-misc/ps3mediaserver/ps3mediaserver-1.60.0.ebuild b/net-misc/ps3mediaserver/ps3mediaserver-1.60.0.ebuild
new file mode 100644
index 000000000000..c65cee590ac7
--- /dev/null
+++ b/net-misc/ps3mediaserver/ps3mediaserver-1.60.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.60.0.ebuild,v 1.1 2012/08/05 03:29:50 floppym Exp $
+
+EAPI="4"
+
+inherit eutils
+
+DESCRIPTION="DLNA compliant UPNP server for streaming media to Playstation 3"
+HOMEPAGE="http://code.google.com/p/ps3mediaserver"
+SRC_URI="http://ps3mediaserver.googlecode.com/files/pms-generic-linux-unix-${PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="multiuser +transcode tsmuxer"
+
+DEPEND="app-arch/unzip"
+RDEPEND=">=virtual/jre-1.6.0
+	|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
+	media-libs/libmediainfo
+	media-libs/libzen
+	tsmuxer? ( media-video/tsmuxer )
+	transcode? ( media-video/mplayer[encode] )"
+
+S=${WORKDIR}/pms-${PV}
+PMS_HOME=/opt/${PN}
+
+src_prepare() {
+	if use multiuser; then
+		cat > ${PN} <<-EOF
+		#!/bin/sh
+		if [ ! -e ~/.${PN} ]; then
+			echo "Copying ${PMS_HOME} to ~/.${PN}"
+			cp -pPR "${PMS_HOME}" ~/.${PN}
+		fi
+		export PMS_HOME=\${HOME}/.${PN}
+		exec "\${PMS_HOME}/PMS.sh" "\$@"
+		EOF
+	else
+		cat > ${PN} <<-EOF
+		#!/bin/sh
+		export PMS_HOME=${PMS_HOME}
+		exec "\${PMS_HOME}/PMS.sh" "\$@"
+		EOF
+	fi
+
+	cat > ${PN}.desktop <<-EOF
+	[Desktop Entry]
+	Name=PS3 Media Server
+	GenericName=Media Server
+	Exec=${PN}
+	Icon=${PN}
+	Type=Application
+	Categories=Network;
+	EOF
+
+	unzip -j pms.jar resources/images/icon-{32,256}.png || die
+}
+
+src_install() {
+	dobin ${PN}
+
+	exeinto ${PMS_HOME}
+	doexe PMS.sh
+
+	insinto ${PMS_HOME}
+	doins -r pms.jar *.conf documentation plugins renderers *.xml
+	use tsmuxer && dosym /opt/tsmuxer/bin/tsMuxeR ${PMS_HOME}/linux/tsMuxeR
+	dodoc CHANGELOG README.md
+
+	newicon -s 32 icon-32.png ${PN}.png
+	newicon -s 256 icon-256.png ${PN}.png
+
+	domenu ${PN}.desktop
+
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+	newinitd "${FILESDIR}/${PN}.initd" ${PN}
+}
+
+pkg_postinst() {
+	ewarn "Don't forget to disable transcoding engines for software"
+	ewarn "that you don't have installed (such as having the VLC"
+	ewarn "transcoding engine enabled when you only have mencoder)."
+	if use multiuser; then
+		echo
+		ewarn "Make sure to refresh the .${PN} in your home directory if you are"
+		ewarn "upgrading from a previous version."
+	fi
+}